app-arch/7zip: add 24.09

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 113 insertions, 0 deletions

diff --git a/app-arch/7zip/7zip-24.09.ebuild b/app-arch/7zip/7zip-24.09.ebuild
new file mode 100644
index 000000000000..65deea631e60
--- /dev/null
+++ b/app-arch/7zip/7zip-24.09.ebuild
@@ -0,0 +1,111 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edos2unix flag-o-matic toolchain-funcs
+
+NO_DOT_PV=$(ver_rs 1- '')
+DESCRIPTION="Free file archiver for extremely high compression"
+HOMEPAGE="https://www.7-zip.org/ https://sourceforge.net/projects/sevenzip/"
+# linux-x64 tarball is only used for docs
+SRC_URI="
+	https://downloads.sourceforge.net/sevenzip/7-Zip/${PV}/7z${NO_DOT_PV}-src.tar.xz
+	https://downloads.sourceforge.net/sevenzip/7-Zip/${PV}/7z${NO_DOT_PV}-linux-x64.tar.xz
+"
+S="${WORKDIR}"
+
+LICENSE="LGPL-2 BSD rar? ( unRAR )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv"
+IUSE="uasm jwasm rar"
+REQUIRED_USE="?? ( uasm jwasm )"
+
+DOCS=( readme.txt History.txt License.txt )
+HTML_DOCS=( MANUAL )
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-arch/xz-utils[extra-filters(+)]
+	uasm? ( dev-lang/uasm )
+	jwasm? ( dev-lang/jwasm )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-24.05-respect-build-env.patch"
+)
+
+# TODO(NRK): also build and install the library
+# TODO(NRK): make it so this package can be used as a drop-in replacement
+# for app-arch/p7zip ??
+
+pkg_setup() {
+	# instructions in DOC/readme.txt, Compiling 7-Zip for Unix/Linux
+	# TLDR; every combination of options (clang|gcc)+(asm/noasm)
+	# has a dedicated makefile & builddir
+	mfile="cmpl"
+	if tc-is-clang; then
+		mfile="${mfile}_clang"
+		bdir=c
+	elif tc-is-gcc; then
+		mfile="${mfile}_gcc"
+		bdir=g
+	else
+		die "Unsupported compiler: $(tc-getCC)"
+	fi
+	if use jwasm || use uasm ; then
+		mfile="${mfile}_x64"
+		bdir="${bdir}_x64"
+	fi
+	export mfile="${mfile}.mak"
+	export bdir
+}
+
+src_prepare() {
+	# patch doesn't deal with CRLF even if file+patch match
+	# not even with --ignore-whitespace, --binary or --force
+	pushd "./CPP/7zip" || die "Unable to switch directory"
+	edos2unix ./7zip_gcc.mak ./var_gcc{,_x64}.mak ./var_clang{,_x64}.mak
+	sed -i -e 's/-Werror //g' ./7zip_gcc.mak || die "Error removing -Werror"
+	popd >/dev/null || die "Unable to switch directory"
+
+	default
+}
+
+src_compile() {
+	pushd "./CPP/7zip/Bundles/Alone2" || die "Unable to switch directory"
+
+	# avoid executable stack when using uasm/jwasm, harmless otherwise
+	append-ldflags -Wl,-z,noexecstack
+	export G_CFLAGS=${CFLAGS}
+	export G_CXXFLAGS=${CXXFLAGS}
+	export G_LDFLAGS=${LDFLAGS}
+
+	local args=(
+		-f "../../${mfile}"
+		CC=$(tc-getCC)
+		CXX=$(tc-getCXX)
+	)
+	# NOTE: makefile doesn't check the value of DISABLE_RAR_COMPRESS, only
+	# whether it's defined or not. so in case user has `rar` enabled
+	# DISABLE_RAR_COMPRESS (and DISABLE_RAR) needs to stay undefined.
+	if ! use rar; then
+		# disables non-free rar code but allows listing and extracting
+		# non-compressed rar archives
+		args+=( DISABLE_RAR_COMPRESS=1 )
+	fi
+	if use jwasm; then
+		args+=( USE_JWASM=1 )
+	elif use uasm; then
+		args+=( MY_ASM=uasm )
+	fi
+
+	mkdir -p "${bdir}" || die  # Bug: https://bugs.gentoo.org/933619
+	emake ${args[@]}
+	popd > /dev/null || die "Unable to switch directory"
+}
+
+src_install() {
+	dobin "./CPP/7zip/Bundles/Alone2/b/${bdir}/7zz"
+	einstalldocs
+}
diff --git a/app-arch/7zip/Manifest b/app-arch/7zip/Manifest
index a3172bd3e9b9..0080f01dee42 100644
--- a/app-arch/7zip/Manifest
+++ b/app-arch/7zip/Manifest
@@ -2,3 +2,5 @@ DIST 7z2407-linux-x64.tar.xz 1554932 BLAKE2B 9229fdac09148c50032656743aba0f8ce1e
 DIST 7z2407-src.tar.xz 1488556 BLAKE2B 42b4f9553aaa4797e80a2d50073ff0e77b5261e50766f8c596a632fb013ac1514a2963f27b924485f07728d13a4536c69911867e3728e8f8604ec25fc4c6824e SHA512 0299e5c1e1dfd33ecf22077f812da1f25bf2146a713c7a7e2498d639520f21f029e853914e66a84d1edfc5d721e1f3d914a3171ab336a406a94bc82d5b2d8e5d
 DIST 7z2408-linux-x64.tar.xz 1556956 BLAKE2B 177b355830201e48d314667c1936e3ca0b624b3fd47b8696df78cc27bb559fd239c1ab2146a88111c3bd1ef1396e694d235babb9b8391fc55cac89c97d7990bd SHA512 00b8d2b89e1410e360cf034c44a43cb88927d76317ee291519ef1f39e3cab68b5549de66f0f6b867f0367d50e7661f484e0a0f7afdd2ecb963804e44c789d7ce
 DIST 7z2408-src.tar.xz 1493700 BLAKE2B fd22a302044ca8655187573173fdc13ae93efaf907cb60076600013e3f463912b876cc3764853ce9d1850fc10dc264cd96917ef6dca9332541db292aee3f1ab4 SHA512 889e9aeaa629d6474a609a15066b2fa7b1353fa5e7255e044297591f565b08b16b885d44f4c4a046f2f9da189599ace300cf61fd9ac0e7bc316fb9d96a18a039
+DIST 7z2409-linux-x64.tar.xz 1565344 BLAKE2B 4ded059fe85073405b4a1510378ed473bca6de2792d313fc3dcb77850dc2531b06866bb4d9de4d4dbc848be5a98b2e4cf5bbe191248f0ae53a279b48b586c169 SHA512 aebf18d861944e2b52d91434b1d59d80a5aadf3b2e80ab3d248357bcaf3c429442caf4ad3297057a559f2719cae9ce5b0aa391963570ffa75b6dcdf1f3c25603
+DIST 7z2409-src.tar.xz 1511288 BLAKE2B 5fcb39acc282b7dafbd1900eaf77e15e634adda5eff5d630b9d0821aa0d1e8569856cf99503ab7ffe69a82cec82a1a890772d6cff86cdb0af01dd462a94c0908 SHA512 461b702eb275655ebda70e128a5e184d15d2b0556f11ab1b409c0ff8a1e9c5d64761bdfb1685c5a0278534024a1e4ce46e4443d55cae373e487dc9ae180ef310