media-gfx/opentoonz: add 1.6.0

Closes: https://bugs.gentoo.org/830892
Closes: https://bugs.gentoo.org/859778
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/media-gfx/opentoonz/Manifest b/media-gfx/opentoonz/Manifest
index 71e06c6c4845..af143750da35 100644
--- a/media-gfx/opentoonz/Manifest
+++ b/media-gfx/opentoonz/Manifest
@@ -1 +1,2 @@
 DIST opentoonz-1.4.0.tar.gz 53531141 BLAKE2B adb7a85fb0581d92119b5f6b75dc320428ea0763955f8c883072cba78045acdeea75a5cea82065a29d2c59f53b4843d8ff92690c9a47c01605b4702fd36d6c13 SHA512 777f5d59ec8076e1e53a81347e15bef198bea77449073f1e9d5fdd371a61e20fd6dc8b26c6656c783959782bd71008fbb63c05742aaa50c92bd317aded7d0649
+DIST opentoonz-1.6.0.tar.gz 55011226 BLAKE2B e7e27d530ee8356071d38bb3d58de89edcdc6e7e0b28cdb9ba8f7681eda929e13211664a5502499aa3eccfcf090ad81970e9caef365e762b53b7a57f19310afe SHA512 5ee7b724d51f058867d2c7e9c540e68ee3cb6d1350e32c5fd817b10b92ad79cc2a106d36dccc9234503e62788903e6058841dcd8dc39450c889393d0300636e9
diff --git a/media-gfx/opentoonz/opentoonz-1.6.0.ebuild b/media-gfx/opentoonz/opentoonz-1.6.0.ebuild
new file mode 100644
index 000000000000..455a47d16a18
--- /dev/null
+++ b/media-gfx/opentoonz/opentoonz-1.6.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_MAKEFILE_GENERATOR=emake
+inherit cmake flag-o-matic xdg-utils
+
+DESCRIPTION="An open-source full-featured 2D animation creation software"
+HOMEPAGE="https://github.com/opentoonz/opentoonz"
+SRC_URI="https://github.com/opentoonz/opentoonz/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD libtiff"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+RDEPEND="
+	app-arch/lz4:=
+	dev-libs/boost:=
+	dev-libs/lzo:2
+	>=dev-qt/qtcore-5.9:5
+	>=dev-qt/qtgui-5.9:5
+	>=dev-qt/qtmultimedia-5.9:5[widgets]
+	>=dev-qt/qtnetwork-5.9:5
+	>=dev-qt/qtopengl-5.9:5
+	>=dev-qt/qtprintsupport-5.9:5
+	>=dev-qt/qtscript-5.9:5
+	>=dev-qt/qtserialport-5.9:5
+	>=dev-qt/qtsvg-5.9:5
+	>=dev-qt/qtwidgets-5.9:5
+	>=dev-qt/qtxml-5.9:5
+	media-libs/freeglut
+	media-libs/freetype:2
+	media-libs/glew:=
+	media-libs/libjpeg-turbo
+	>=media-libs/libmypaint-1.3.0:=
+	media-libs/libpng:=
+	media-libs/opencv:=
+	>=sci-libs/superlu-4.1:=
+	sys-libs/zlib
+	virtual/cblas
+	virtual/libusb:1
+	virtual/opengl
+"
+DEPEND="${RDEPEND}"
+
+CMAKE_USE_DIR="${S}"/toonz/sources
+
+src_configure() {
+	# bug #859778
+	append-flags -fno-strict-aliasing
+	filter-lto
+
+	local mycmakeargs=(
+		-DTIFF_LIBRARY="${S}/thirdparty/tiff-4.0.3/libtiff/.libs/libtiff.a"
+		-DSUPERLU_INCLUDE_DIR="${EPREFIX}/usr/include/superlu"
+		-DLZO_INCLUDE_DIR="${EPREFIX}/usr/include/lzo"
+		-DCMAKE_SKIP_RPATH=ON
+	)
+
+	# The upstream uses their own modified libtiff
+	# See: https://github.com/opentoonz/opentoonz/blob/master/doc/how_to_build_linux.md#building-libtiff
+	cd thirdparty/tiff-4.0.3 || die
+	CONFIG_SHELL="${BROOT}"/bin/bash econf \
+		--with-pic \
+		--disable-jbig \
+		--enable-static \
+		--disable-shared
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cd "${S}"/thirdparty/tiff-4.0.3 || die
+	emake
+
+	cmake_src_compile
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}