media-libs/gegl: 0.3.20

Also sync live ebuild

Package-Manager: Portage-2.3.8, Repoman-2.3.3

3 files changed, 189 insertions, 21 deletions

diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index f0a938a4c564..4dfa63cae688 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -3,5 +3,6 @@ DIST gegl-0.3.0.tar.bz2 5463571 SHA256 f0fec8f2e7b8835979d3cf4e38b05d41bb79f68dc
 DIST gegl-0.3.10.tar.bz2 5905157 SHA256 26b4d6d0a8edb358ca2fbc097f9f97eec9d74e0ffe42f89fa1aff201728023d9 SHA512 54df7e0cb26be2f2664eb9373fc2e1dff809df505007c95e72c896f3e2829e2159df7b9701c31b4dc20953a9476de69d603e8d5c1c42078284edfa6cf05dccd7 WHIRLPOOL c307bcb65287489c98e3cae50a57c6215e29eeef315b7d581c3c5239c8156ddd69b30edd83e35549d4c6b840e6ed15a778a5145f939a7a2e20a70d6b64551439
 DIST gegl-0.3.12.tar.bz2 6037107 SHA256 62eb08d7dd6ac046953a0bf606a71f9d14c9016ffef4ef7273b07b598f14bec7 SHA512 a8c9d1d21b042d2c848a540f69f58c2224c6617e21a6e25b47eb885a0388242195569a81101242041eba2b7c486dbbc47f516fae8d7ab35f4d67ab5f5c2b0fe4 WHIRLPOOL 2f7846f80238d525cf160ad07b5dc96d52f081a35a5ac2455c1c7eab65cd09d9acb048ed361ec99a033f16562ac505943e845a5f4e7e1f363840f7721fd99a93
 DIST gegl-0.3.14.tar.bz2 5985306 SHA256 09f5e2e6899697641d4660e3e274aed696f5bacc96ba389ac77674ee1156590a SHA512 8d03bb15433777af3baae20bb987587cef2ae80315116e7e8a3197278c3ca2ff2814aa533ebe2ad4c2cca58a618a8a24b0b6faff0d0ce1194e3d31cfe85beaf9 WHIRLPOOL 1be1914cae5760bb2b35fc495c409cb927783f303cff393f0cdc43a875b42b380829cec9c8907d19c1f78cb57bed5d639759f09bb434c48436d1bc59750ab33d
+DIST gegl-0.3.20.tar.bz2 5816967 SHA256 821568d17dc92a46f6105644c4f4d497daea2be794006140a016ed34e05eb084 SHA512 9067467e3d4bbfe00594a8459c9ea15047c1331764dd3aa2331da7d842a77c98894e3a0e19a7c0b1cb59189ffe03561e9bd12f92bdb8fdf1799afc6a575962f7 WHIRLPOOL 77ffffcce3d8e517b982918974df50e751469e56c58d6c4321f85b295444edd11ae5b7feabdd618fbd82ad7a3546dd550d06ff738f6ca97ffa5e114987bf6604
 DIST gegl-0.3.4.tar.bz2 5328192 SHA256 846290a790854d1e6b7c17a2d6f82ad7cb14c72e240bd3b81b98cc0ceddbc3ec SHA512 7fe14c1534d61cfc253bce54cc707f93882ad96302068fe672e6cdcb613430e835ee5d39a5398537f845a6d101eed6fd3d1ff7e4204d51bc9ab5a59c9e09d2ec WHIRLPOOL 046af673b5a21a050555fabf5e52532b5de7af289922991f0c15cc39a09d32302a6a98483bd4ff2cee3a37356d0cf0e267c87f524f3b6678eb61fcaab6d6735c
 DIST gegl-0.3.8.tar.bz2 5876259 SHA256 06ca9e67a59da026eb941b9d323269d7c19a922f1e478acdd3791a0eef8b229b SHA512 13207e7ab4723be1e31bdba5e30e5725e93c1adc61bad1413502128730391dbe7eb35419d243c8d0a1d8794341a58188790adacbb10d2a8e68db861c18d21bfb WHIRLPOOL 97e3521e2c95e2b370c8a6ac2724b57212ebfbbf3c1eeccc3cfaa4de6b993c56b32ead9e5baa23dcbcb8272f7ec29ce7a2acc3afcc5fcc062d0adc72899293b8
diff --git a/media-libs/gegl/gegl-0.3.20.ebuild b/media-libs/gegl/gegl-0.3.20.ebuild
new file mode 100644
index 000000000000..1c12a597ceef
--- /dev/null
+++ b/media-libs/gegl/gegl-0.3.20.ebuild
@@ -0,0 +1,177 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit versionator gnome2-utils eutils autotools python-any-r1 vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="git://git.gnome.org/gegl"
+	SRC_URI=""
+else
+	SRC_URI="http://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="http://www.gegl.org/"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0.3"
+
+IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg2k lcms lensfun openexr raw sdl svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	vala? ( introspection )
+"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	dev-libs/json-glib
+	>=media-libs/babl-0.1.30
+	sys-libs/zlib
+	>=x11-libs/gdk-pixbuf-2.32:2
+	x11-libs/pango
+
+	cairo? ( x11-libs/cairo )
+	ffmpeg? (
+		>=media-video/ffmpeg-2.8:0=
+	)
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	virtual/jpeg:0=
+	jpeg2k? ( >=media-libs/jasper-1.900.1:= )
+	lcms? ( >=media-libs/lcms-2.2:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( media-libs/openexr:= )
+	media-libs/libpng:0=
+	raw? ( >=media-libs/libraw-0.15.4:0= )
+	sdl? ( media-libs/libsdl )
+	svg? ( >=gnome-base/librsvg-2.14:2 )
+	tiff? ( >=media-libs/tiff-4:0 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( media-libs/libwebp )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.40.1
+	dev-lang/perl
+	virtual/pkgconfig
+	>=sys-devel/libtool-2.2
+	test? ( introspection? (
+		$(python_gen_any_dep '>=dev-python/pygobject-3.2[${PYTHON_USEDEP}]') ) )
+	vala? ( $(vala_depend) )
+"
+
+pkg_setup() {
+	use test && use introspection && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# FIXME: the following should be proper patch sent to upstream
+	# fix OSX loadable module filename extension
+	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	# commit 7c78497b : tests that use gegl.png are broken on non-amd64
+	sed -e '/clones.xml/d' \
+		-e '/composite-transform.xml/d' \
+		-i tests/compositions/Makefile.am || die
+
+	epatch "${FILESDIR}"/${PN}-0.3.12-failing-tests.patch
+
+	eautoreconf
+
+	gnome2_environment_reset
+
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	# never enable altering of CFLAGS via profile option
+	# libspiro: not in portage main tree
+	# disable documentation as the generating is bit automagic
+	#    if anyone wants to work on it just create bug with patch
+
+	# Also please note that:
+	#
+	#  - Some auto-detections are not patched away since the docs are
+	#    not built (--disable-docs, lack of --enable-gtk-doc) and these
+	#    tools affect re-generation of docs, only
+	#    (e.g. ruby, asciidoc, dot (of graphviz), enscript)
+	#
+	#  - Parameter --with-exiv2 compiles a noinst-app only, no use
+	#
+	#  - Parameter --disable-workshop disables any use of Lua, effectivly
+	#
+	#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+	#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+	#
+	#  - There are two checks for dot, one controllable by --with(out)-graphviz
+	#    which toggles HAVE_GRAPHVIZ that is not used anywhere.  Yes.
+	#
+	#  - mrg is not in tree and gexiv2 support only has effect when mrg support
+	#    is enabled
+	#
+	# So that's why USE="exif graphviz lua v4l" got resolved.  More at:
+	# https://bugs.gentoo.org/show_bug.cgi?id=451136
+	#
+	econf \
+		--disable-docs \
+		--disable-profile \
+		--disable-silent-rules \
+		--disable-workshop \
+		--program-suffix=-${SLOT} \
+		--with-gdk-pixbuf \
+		--with-pango \
+		--without-libspiro \
+		$(use_enable cpu_flags_x86_mmx mmx) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable debug) \
+		$(use_with cairo) \
+		$(use_with cairo pangocairo) \
+		--without-exiv2 \
+		$(use_with ffmpeg libavformat) \
+		--without-gexiv2 \
+		--without-graphviz \
+		$(use_with jpeg2k jasper) \
+		$(use_with lcms) \
+		$(use_with lensfun) \
+		--without-lua \
+		--without-mrg \
+		$(use_with openexr) \
+		$(use_with raw libraw) \
+		$(use_with sdl) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with umfpack) \
+		$(use_with v4l libv4l) \
+		$(use_with v4l libv4l2) \
+		$(use_enable introspection) \
+		$(use_with vala) \
+		$(use_with webp)
+}
+
+src_compile() {
+	default
+
+	[[ ${PV} == *9999* ]] && emake ./ChangeLog  # "./" prevents "Circular ChangeLog <- ChangeLog dependency dropped."
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
diff --git a/media-libs/gegl/gegl-9999.ebuild b/media-libs/gegl/gegl-9999.ebuild
index 5a903970c2b7..927662caeff6 100644
--- a/media-libs/gegl/gegl-9999.ebuild
+++ b/media-libs/gegl/gegl-9999.ebuild
@@ -1,12 +1,10 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
-
 PYTHON_COMPAT=( python2_7 )
 
 # vala and introspection support is broken, bug #468208
-VALA_MIN_API_VERSION=0.20
 VALA_USE_DEPEND=vapigen
 
 inherit versionator gnome2-utils eutils autotools python-any-r1 vala
@@ -26,18 +24,18 @@ HOMEPAGE="http://www.gegl.org/"
 LICENSE="|| ( GPL-3 LGPL-3 )"
 SLOT="0.3"
 
-IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg jpeg2k lcms lensfun libav openexr png raw sdl svg test tiff umfpack vala v4l webp"
+IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg2k lcms lensfun libav openexr raw sdl svg test tiff umfpack vala v4l webp"
 REQUIRED_USE="
 	svg? ( cairo )
 	vala? ( introspection )
 "
 
 RDEPEND="
-	>=dev-libs/glib-2.36:2
+	>=dev-libs/glib-2.44:2
 	dev-libs/json-glib
-	>=media-libs/babl-0.1.14
+	>=media-libs/babl-0.1.30
 	sys-libs/zlib
-	>=x11-libs/gdk-pixbuf-2.18:2
+	>=x11-libs/gdk-pixbuf-2.32:2
 	x11-libs/pango
 
 	cairo? ( x11-libs/cairo )
@@ -45,14 +43,14 @@ RDEPEND="
 		libav? ( media-video/libav:0= )
 		!libav? ( media-video/ffmpeg:0= )
 	)
-	introspection? ( >=dev-libs/gobject-introspection-1.32 )
-	jpeg? ( virtual/jpeg:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	virtual/jpeg:0=
 	jpeg2k? ( >=media-libs/jasper-1.900.1:= )
 	lcms? ( >=media-libs/lcms-2.2:2 )
 	lensfun? ( >=media-libs/lensfun-0.2.5 )
 	openexr? ( media-libs/openexr:= )
-	png? ( media-libs/libpng:0= )
-	raw? ( >=media-libs/libraw-0.15.4 )
+	media-libs/libpng:0=
+	raw? ( >=media-libs/libraw-0.15.4:0= )
 	sdl? ( media-libs/libsdl )
 	svg? ( >=gnome-base/librsvg-2.14:2 )
 	tiff? ( >=media-libs/tiff-4:0 )
@@ -86,8 +84,6 @@ src_prepare() {
 		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
 	fi
 
-	#epatch "${FILESDIR}"/${P}-g_log_domain.patch
-
 	# commit 7c78497b : tests that use gegl.png are broken on non-amd64
 	sed -e '/clones.xml/d' \
 		-e '/composite-transform.xml/d' \
@@ -95,6 +91,8 @@ src_prepare() {
 
 	eautoreconf
 
+	gnome2_environment_reset
+
 	use vala && vala_src_prepare
 }
 
@@ -145,14 +143,12 @@ src_configure() {
 		$(use_with ffmpeg libavformat) \
 		--without-gexiv2 \
 		--without-graphviz \
-		$(use_with jpeg libjpeg) \
 		$(use_with jpeg2k jasper) \
 		$(use_with lcms) \
 		$(use_with lensfun) \
 		--without-lua \
 		--without-mrg \
 		$(use_with openexr) \
-		$(use_with png libpng) \
 		$(use_with raw libraw) \
 		$(use_with sdl) \
 		$(use_with svg librsvg) \
@@ -165,13 +161,7 @@ src_configure() {
 		$(use_with webp)
 }
 
-src_test() {
-	gnome2_environment_reset  # sandbox issues
-	default
-}
-
 src_compile() {
-	gnome2_environment_reset  # sandbox issues (bug #396687)
 	default
 
 	[[ ${PV} == *9999* ]] && emake ./ChangeLog  # "./" prevents "Circular ChangeLog <- ChangeLog dependency dropped."