dev-python/oslo-config: remove incorrect rdepend on importlib-metadata

The original implementation of importlib-metadata in oslo.config used
the stdlib importlib.metadata, for python >=3.8.

https://opendev.org/openstack/oslo.config/commit/392922aa333f9777f98e7ce61ad46f69cd9ac455

Signed-off-by: Eli Schwartz <eschwartz93@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-python/oslo-config/oslo-config-9.2.0-r1.ebuild b/dev-python/oslo-config/oslo-config-9.2.0-r1.ebuild
new file mode 100644
index 000000000000..dcca108e37a4
--- /dev/null
+++ b/dev-python/oslo-config/oslo-config-9.2.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Oslo Configuration API"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.config/
+	https://github.com/openstack/oslo.config/
+	https://pypi.org/project/oslo.config/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~riscv x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.5.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# broken by some dep upgrade
+	sed -i -e '/DeprecationWarningTestsNoOsloLog/,$d' \
+		oslo_config/tests/test_cfg.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x COLUMNS=80
+	eunittest -b
+}