app-admin/cgmanager: bump to 0.39

There is a new pam module added. Had to patch the
automagic deps for it

Package-Manager: portage-2.2.20.1

1 files changed, 53 insertions, 0 deletions

diff --git a/app-admin/cgmanager/cgmanager-0.39.ebuild b/app-admin/cgmanager/cgmanager-0.39.ebuild
new file mode 100644
index 000000000000..a31daac011f1
--- /dev/null
+++ b/app-admin/cgmanager/cgmanager-0.39.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit autotools pam
+
+DESCRIPTION="Control Group manager daemon"
+HOMEPAGE="https://linuxcontainers.org/cgmanager/introduction/"
+SRC_URI="https://linuxcontainers.org/downloads/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="pam"
+
+RDEPEND="
+	sys-libs/libnih[dbus]
+	sys-apps/dbus"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch_user
+
+	# systemd expects files in /sbin but we will have them in /usr/sbin
+	pushd config/init/systemd > /dev/null || die
+	sed -i -e "s@sbin@usr/&@" {${PN},cgproxy}.service || \
+		die "Failed to fix paths in systemd service files"
+	popd > /dev/null || die
+
+	# there is an automagic dep on pam
+	epatch "${FILESDIR}/${PN}-0.39-make-pam-conditional.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-distro=gentoo \
+		$(use_enable pam pam-module) \
+		--with-pamdir="$(getpam_mod_dir)" \
+		--with-init-script=systemd
+}
+
+src_install () {
+	default
+
+	# I see no reason to have the tests in the filesystem. Drop them
+	rm -r "${D}"/usr/share/${PN}/tests || die "Failed to remove ${PN} tests"
+
+	newinitd "${FILESDIR}"/${PN}.initd-r1 ${PN}
+	newinitd "${FILESDIR}"/cgproxy.initd-r1 cgproxy
+}