app-admin/system-config-printer: Version bump to 1.5.18

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/app-admin/system-config-printer/Manifest b/app-admin/system-config-printer/Manifest
index 64bc94b0aedc..06675bedc70f 100644
--- a/app-admin/system-config-printer/Manifest
+++ b/app-admin/system-config-printer/Manifest
@@ -1,2 +1,3 @@
 DIST system-config-printer-1.5.16.tar.xz 1382124 BLAKE2B 37548bd470f8e80026e014d4077a79a38ad54258d620654536890b67b688fc790c9a9a269b321f2e12d63ec21f24858866e39b41089195c528ddbdf1351bba5f SHA512 ed20a409def66bdea7de4cd5b397891eca220c841e1b5c8cab98e45f87389ae8ba881d9e24072dd07203141fc34c49c4b67cf099791857c007971e3b7d2e2fc2
 DIST system-config-printer-1.5.17.tar.xz 1385792 BLAKE2B c17dce0ef2988028a95e4ad7b9ead18aa13ab07452f5df9a6fb07f4728ce2ed7aa51e8997e7086d517f6965ec1f306fbd6e7f68683e6da66d18bc75408af9220 SHA512 e56fb45e76a93de122bef99774574f77168014b855cd75e1939fb2d6e56ddb27496679a7932cd6255b950599541c3fb3b82386735bfb6dc13eed59f9a259668e
+DIST system-config-printer-1.5.18.tar.xz 1396808 BLAKE2B 910e853829ee876edc597a3103b5ab857b3b8c1cb87096f25213b1088e35d9f4d320dad61f55b530283a7650b07abe028a53b4e144b33b1b66c733cb2caa8011 SHA512 33dc9c52d92f4234e055fb10a99cadd58424dcdb62554797b44bdd5319f1c3662bd2fa33417ac3a3f5ec51216d64e81e1897f3e671eb49f6be34057d7c38f3f4
diff --git a/app-admin/system-config-printer/system-config-printer-1.5.18.ebuild b/app-admin/system-config-printer/system-config-printer-1.5.18.ebuild
new file mode 100644
index 000000000000..b3d54f6d76b2
--- /dev/null
+++ b/app-admin/system-config-printer/system-config-printer-1.5.18.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml"
+inherit python-single-r1 systemd udev xdg
+
+DESCRIPTION="Graphical user interface for CUPS administration"
+HOMEPAGE="https://github.com/OpenPrinting/system-config-printer"
+SRC_URI="https://github.com/OpenPrinting/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gnome-keyring policykit"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Needs cups running, bug 284005
+RESTRICT="test"
+
+# Additional unhandled dependencies
+# gnome-extra/gnome-packagekit[${PYTHON_USEDEP}] with pygobject:2 ?
+# python samba client: smbc
+# selinux: needed for troubleshooting
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-libs/glib:2
+	net-print/cups[dbus]
+	virtual/libusb:1
+	>=virtual/udev-172
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	>=app-text/xmlto-0.0.22
+	dev-perl/XML-Parser
+	dev-util/desktop-file-utils
+	>=sys-devel/gettext-0.20
+	virtual/pkgconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pycups[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+	')
+	gnome-keyring? ( app-crypt/libsecret[introspection] )
+	policykit? ( net-print/cups-pk-helper )
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-xmlto
+		--enable-nls
+		--with-desktop-vendor=Gentoo
+		--with-udev-rules
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+	python_optimize cupshelpers
+}
+
+src_install() {
+	default
+	python_fix_shebang "${ED}"
+	python_optimize
+	python_domodule cupshelpers
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}