app-emulation/winetricks: Sync with ::wine

Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/app-emulation/winetricks/Manifest b/app-emulation/winetricks/Manifest
index 0e90059e5f16..23eabc5f7daf 100644
--- a/app-emulation/winetricks/Manifest
+++ b/app-emulation/winetricks/Manifest
@@ -1,2 +1,3 @@
 DIST winetricks-20210206.tar.gz 690837 BLAKE2B a1d068e9659f6b176873af49994f1e0ca884eaa1ac9b8f5dd6d7abe79a2b8b827a2334efa7862547b17cca5bcfc285ce2d65ac0e5736cddcc777d4df2dbc7af9 SHA512 57f2ce5fe531eb6ee9a578ca565fadf5ef2e6e1379abee640ee9dc0d6000c92ce983c7507002bc6ace613d6d0dd03260ede11f7bf267adf19eb67900a0449f58
+DIST winetricks-20210825.tar.gz 689728 BLAKE2B 32fc9639f215180e03c79d55359c7aa005c005ed6a3a21916de7172dc541994a786b64f8323034b3e43e0619569b39f79dc98830546db1d684badf96cdb898c4 SHA512 b9eb61a0bfe4001cb23f41f3b4707333be81660372347b5e8fe887fe1e2278bd5e2b91e0c5ddd73010652902a8985f0e253792c8769216de397ca75fac8b0c81
 DIST winetricks-gentoo-2012.11.24.tar.bz2 6398 BLAKE2B 54a4502f6e8ef15d21b02c43e3ce599e32d476c2559246064de14cc4ce2243ff11dde681d24c8a7f4913c3d7a10b855bda47e8fb8ecad31e00d839705416be6f SHA512 59c93b73f3a7b2d11aefcde2ff66659ff1de21ad4b5f232f4b60572f3a48b15a6c49f369b1696862bf1b33fde190bf5598945e9536fb41ddec42d8def4d2be2a
diff --git a/app-emulation/winetricks/winetricks-20210825.ebuild b/app-emulation/winetricks/winetricks-20210825.ebuild
new file mode 100644
index 000000000000..89dcbb57c973
--- /dev/null
+++ b/app-emulation/winetricks/winetricks-20210825.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg
+
+if [[ ${PV} == "99999999" ]] ; then
+	EGIT_REPO_URI="https://github.com/Winetricks/${PN}.git"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+wtg="winetricks-gentoo-2012.11.24"
+
+SRC_URI="${SRC_URI}
+	gtk? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+	kde? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+"
+
+DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
+HOMEPAGE="https://github.com/Winetricks/winetricks https://wiki.winehq.org/Winetricks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk kde rar test"
+RESTRICT="!test? ( test )"
+
+# dev-util/shellcheck is not available for x86
+RESTRICT+=" x86? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/bashate
+		dev-util/checkbashisms
+		|| (
+			dev-util/shellcheck-bin
+			dev-util/shellcheck
+		)
+	)
+"
+DEPEND=""
+RDEPEND="${DEPEND}
+	app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	net-misc/wget
+	virtual/wine
+	x11-misc/xdg-utils
+	gtk? ( gnome-extra/zenity )
+	kde? ( kde-apps/kdialog )
+	rar? ( app-arch/unrar )
+"
+
+# Test targets include syntax checks only, not the "heavy duty" tests
+# that would require a lot of disk space, as well as network access.
+
+# This uses a non-standard "Wine" category, which is provided by
+# '/etc/xdg/menus/applications-merged/wine.menu' from the
+# 'app-emulation/wine-desktop-common' package.
+# https://bugs.gentoo.org/451552
+QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]]; then
+		git-r3_src_unpack
+
+		if use gtk || use kde; then
+			unpack ${wtg}.tar.bz2
+		fi
+
+	else
+		default
+	fi
+}
+
+src_test() {
+	./tests/shell-checks || die "Test(s) failed."
+}
+
+src_install() {
+	default
+
+	if ! use gtk && ! use kde; then
+		rm -r "${ED}"/usr/share/applications || die
+		rm -r "${ED}"/usr/share/icons || die
+	fi
+}