app-i18n/libskk: new upstream release

Gentoo-Bug: 608862

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 47 insertions, 0 deletions

diff --git a/app-i18n/libskk/libskk-1.0.2.ebuild b/app-i18n/libskk/libskk-1.0.2.ebuild
new file mode 100644
index 000000000000..c03b9f52026e
--- /dev/null
+++ b/app-i18n/libskk/libskk-1.0.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit ltprune virtualx vala
+
+DESCRIPTION="GObject-based library to deal with Japanese kana-to-kanji conversion method"
+HOMEPAGE="https://github.com/ueno/libskk"
+SRC_URI="https://github.com/ueno/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection nls static-libs"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libgee:0.8
+	introspection? ( dev-libs/gobject-introspection )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	vala_src_prepare
+	default
+}
+
+src_configure() {
+	econf \
+		$(use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable static-libs static)
+}
+
+src_test() {
+	Xemake check
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}