Revert "app-portage/layman: treeclean"

This reverts commit 805fe7c0495e1bf3a34d518041e466258944b82b.

Signed-off-by: Jakov Smolić <jsmolic@gentoo.org>

4 files changed, 225 insertions, 0 deletions

diff --git a/app-portage/layman/Manifest b/app-portage/layman/Manifest
new file mode 100644
index 000000000000..0d796db12b72
--- /dev/null
+++ b/app-portage/layman/Manifest
@@ -0,0 +1 @@
+DIST layman-2.4.3.tar.gz 135311 BLAKE2B b83fd543468be904a10d6fbda11f8d603a6936ecef3029c9d1c82fe4c938d2cd299874a3e114ac3524485ce8a33c5ec21885adddc218f5e331519318c0b1ad5a SHA512 2f3d1180647b358d5ca929fd28c6c5f4664f1f6f24e3114a4dc886d23279ffcdde7ca292c64aab84f1710ddf7029c26483de07c2271ca527b8618888b0ea2b54
diff --git a/app-portage/layman/layman-2.4.3.ebuild b/app-portage/layman/layman-2.4.3.ebuild
new file mode 100644
index 000000000000..6582164422ad
--- /dev/null
+++ b/app-portage/layman/layman-2.4.3.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+PYTHON_REQ_USE="xml(+),sqlite?"
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 linux-info prefix
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/layman.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+DESCRIPTION="Tool to manage Gentoo overlays"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Layman"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="cvs darcs +git gpg g-sorcery mercurial sqlite squashfs subversion sync-plugin-portage test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-vcs/subversion )"
+RDEPEND="
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	g-sorcery? ( app-portage/g-sorcery )
+	subversion? ( >=dev-vcs/subversion-1.5.4[http(+)] )
+	gpg? ( >=dev-python/pyGPG-0.2 )
+	sync-plugin-portage? ( >=sys-apps/portage-2.2.16[${PYTHON_USEDEP}] )
+	!sync-plugin-portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
+	>=dev-python/ssl-fetch-0.4[${PYTHON_USEDEP}]
+"
+
+if [[ ${PV} == *9999 ]]; then
+	BDEPEND+=" app-text/asciidoc"
+fi
+
+layman_check_kernel_config() {
+	local CONFIG_CHECK
+	use squashfs && CONFIG_CHECK+=" ~BLK_DEV_LOOP ~SQUASHFS"
+	[[ -n ${CONFIG_CHECK} ]] && check_extra_config
+}
+
+pkg_pretend() {
+	layman_check_kernel_config
+}
+
+pkg_setup() {
+	layman_check_kernel_config
+}
+
+python_prepare_all() {
+	python_setup
+	esetup.py setup_plugins
+	distutils-r1_python_prepare_all
+	eprefixify etc/layman.cfg layman/config.py
+}
+
+python_test() {
+	suite=layman/tests/external.py
+	PYTHONPATH="." "${PYTHON}" ${suite} || die "test suite '${suite}' failed"
+	unset suite
+}
+
+python_compile_all() {
+	# Generate man page. only required for 9999
+	if [[ ${PV} == *9999 ]] ; then
+		# override MAKEOPTS to prevent build failure
+		emake -j1 -C doc
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/layman
+	doins etc/layman.cfg
+
+	doman doc/layman.8
+	docinto html
+	dodoc doc/layman.8.html
+
+	keepdir /var/lib/layman
+	keepdir /etc/layman/overlays
+}
+
+pkg_postinst() {
+	# now run layman's update utility
+	einfo "Running layman-updater..."
+	"${EROOT}"/usr/bin/layman-updater
+	einfo
+}
diff --git a/app-portage/layman/layman-9999.ebuild b/app-portage/layman/layman-9999.ebuild
new file mode 100644
index 000000000000..763e43a73044
--- /dev/null
+++ b/app-portage/layman/layman-9999.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+PYTHON_REQ_USE="xml(+),sqlite?"
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 linux-info prefix
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/layman.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+DESCRIPTION="Tool to manage Gentoo overlays"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Layman"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="cvs darcs +git gpg g-sorcery mercurial sqlite squashfs subversion sync-plugin-portage test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-vcs/subversion )"
+RDEPEND="
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	g-sorcery? ( app-portage/g-sorcery )
+	subversion? ( >=dev-vcs/subversion-1.5.4[http(+)] )
+	gpg? ( >=dev-python/pyGPG-0.2 )
+	sync-plugin-portage? ( >=sys-apps/portage-2.2.16[${PYTHON_USEDEP}] )
+	!sync-plugin-portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
+	>=dev-python/ssl-fetch-0.4[${PYTHON_USEDEP}]
+"
+
+if [[ ${PV} == *9999 ]]; then
+	BDEPEND+=" app-text/asciidoc"
+fi
+
+layman_check_kernel_config() {
+	local CONFIG_CHECK
+	use squashfs && CONFIG_CHECK+=" ~BLK_DEV_LOOP ~SQUASHFS"
+	[[ -n ${CONFIG_CHECK} ]] && check_extra_config
+}
+
+pkg_pretend() {
+	layman_check_kernel_config
+}
+
+pkg_setup() {
+	layman_check_kernel_config
+}
+
+python_prepare_all() {
+	python_setup
+	esetup.py setup_plugins
+	distutils-r1_python_prepare_all
+	eprefixify etc/layman.cfg layman/config.py
+}
+
+python_test() {
+	suite=layman/tests/external.py
+	PYTHONPATH="." "${PYTHON}" ${suite} || die "test suite '${suite}' failed"
+	unset suite
+}
+
+python_compile_all() {
+	# Generate man page. only required for 9999
+	if [[ ${PV} == *9999 ]] ; then
+		# override MAKEOPTS to prevent build failure
+		emake -j1 -C doc
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/layman
+	doins etc/layman.cfg
+
+	doman doc/layman.8
+	docinto html
+	dodoc doc/layman.8.html
+
+	keepdir /var/lib/layman
+	keepdir /etc/layman/overlays
+}
+
+pkg_postinst() {
+	# now run layman's update utility
+	einfo "Running layman-updater..."
+	"${EROOT}"/usr/bin/layman-updater
+	einfo
+}
diff --git a/app-portage/layman/metadata.xml b/app-portage/layman/metadata.xml
new file mode 100644
index 000000000000..896fca0e0c03
--- /dev/null
+++ b/app-portage/layman/metadata.xml
@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>layman@gentoo.org</email>
+		<name>Gentoo Layman team</name>
+	</maintainer>
+	<use>
+		<flag name="cvs">Support <pkg>dev-vcs/cvs</pkg> based overlays</flag>
+		<flag name="darcs">Support <pkg>dev-vcs/darcs</pkg> based overlays</flag>
+		<flag name="g-sorcery">Support <pkg>app-portage/g-sorcery</pkg> based overlays</flag>
+		<flag name="git">Support <pkg>dev-vcs/git</pkg> based overlays</flag>
+		<flag name="gpg">Support <pkg>app-crypt/gnupg</pkg> signed overlays lists and manifests</flag>
+		<flag name="mercurial">Support <pkg>dev-vcs/mercurial</pkg> based overlays</flag>
+		<flag name="squashfs">Support mounting squashfs image overlays locally read-only</flag>
+		<flag name="subversion">Support <pkg>dev-vcs/subversion</pkg> based overlays</flag>
+		<flag name="sync-plugin-portage">Install the <pkg>sys-apps/portage</pkg> sync module</flag>
+	</use>
+	<upstream>
+		<remote-id type="sourceforge">layman</remote-id>
+		<remote-id type="gentoo">proj/layman</remote-id>
+		<remote-id type="github">gentoo/layman</remote-id>
+	</upstream>
+</pkgmetadata>