app-shells/mpv-bash-completion: verbump to 3.3.17

Package-Manager: Portage-2.3.40, Repoman-2.3.9
Closes: https://github.com/gentoo/gentoo/pull/8731

1 files changed, 51 insertions, 0 deletions

diff --git a/app-shells/mpv-bash-completion/mpv-bash-completion-3.3.17.ebuild b/app-shells/mpv-bash-completion/mpv-bash-completion-3.3.17.ebuild
new file mode 100644
index 000000000000..2aca0b8cc661
--- /dev/null
+++ b/app-shells/mpv-bash-completion/mpv-bash-completion-3.3.17.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit bash-completion-r1
+
+DESCRIPTION="Bash completion for the mpv video player"
+HOMEPAGE="https://2ion.github.io/mpv-bash-completion/"
+SRC_URI="https://github.com/2ion/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="luajit"
+
+COMMON_DEPEND=">=media-video/mpv-0.25.0[cli]"
+RDEPEND="${COMMON_DEPEND}
+	>=app-shells/bash-completion-2.3-r1
+"
+DEPEND="${COMMON_DEPEND}
+	!luajit? ( dev-lang/lua:* )
+	luajit? ( dev-lang/luajit:2 )
+"
+
+src_prepare() {
+	default_src_prepare
+	# Avoid 'mpv' make target that supports lua only.
+	sed -i -e 's|check: mpv|check:|' Makefile || die
+}
+
+src_compile() {
+	# Prevent access violations from completion generation.
+	# See Gentoo bug 656086.
+	addpredict /dev/dri
+
+	$(usex luajit 'luajit' 'lua') gen.lua > mpv || die
+}
+
+src_install() {
+	dobashcomp mpv
+	einstalldocs
+}
+
+pkg_postinst() {
+	if ! has_version 'x11-apps/xrandr'; then
+		elog
+		elog "If you want completion of window sizes, please install 'x11-apps/xrandr'."
+		elog
+	fi
+}