dev-ada/ada_libfswatch: ada binding to libfswatch

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-ada/ada_libfswatch/ada_libfswatch-20201105.ebuild b/dev-ada/ada_libfswatch/ada_libfswatch-20201105.ebuild
new file mode 100644
index 000000000000..fdc6149a32ce
--- /dev/null
+++ b/dev-ada/ada_libfswatch/ada_libfswatch-20201105.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ADA_COMPAT=( gnat_202{0,1} )
+inherit ada
+
+commitId=94c0a5f137b88113a791a148b60e5e7d019d6fa1
+
+DESCRIPTION="Ada binding to the libfswatch library"
+HOMEPAGE="https://github.com/AdaCore/ada_libfswatch"
+SRC_URI="https://github.com/AdaCore/${PN}/tarball/${commitId}
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-3 gcc-runtime-library-exception-3.1"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="${ADA_DEPS}
+	dev-ada/gnatcoll-core[${ADA_USEDEP}]
+	sys-fs/fswatch"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-ada/gprbuild[${ADA_USEDEP}]"
+
+S="${WORKDIR}"/AdaCore-${PN}-${commitId:0:7}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-link.patch
+)
+
+src_prepare() {
+	default
+	mkdir -p generated || die
+	cp /usr/include/libfswatch/c/* generated || die
+	(cd generated && gcc -C -fdump-ada-spec libfswatch.h -D_TIMEZONE_DEFINED) \
+		|| die
+	rm generated/*h || die
+	sed -i \
+		-e "1d" \
+		ada_libfswatch.gpr || die
+}
+
+src_compile() {
+	gprbuild -p -v -P ada_libfswatch -XLIBRARY_TYPE=static \
+		-cargs:C ${CFLAGS} -cargs:Ada ${ADAFLAGS} \
+		|| die
+}
+
+src_install() {
+	gprinstall -v -r -p -P ada_libfswatch -XLIBRARY_TYPE=static \
+		--prefix="${D}"/usr || die
+	einstalldocs
+}