dev-lang/execline: add 2.8.2.0

-fno-stack-protector flag was removed from configure script in upstream
in version 2.7.0.0.

Upstream-commit: 3c3e63f2a72b ("Don't put -fno-stack-protector in default CFLAGS")
Signed-off-by: Petr Vaněk <arkamar@atlas.cz>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-lang/execline/execline-2.8.2.0.ebuild b/dev-lang/execline/execline-2.8.2.0.ebuild
new file mode 100644
index 000000000000..3d3572779e43
--- /dev/null
+++ b/dev-lang/execline/execline-2.8.2.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="A non-interactive scripting language"
+HOMEPAGE="https://www.skarnet.org/software/execline/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="static static-libs"
+
+REQUIRED_USE="static? ( static-libs )"
+
+RDEPEND=">=dev-libs/skalibs-2.10.1.0:=[static-libs?]"
+DEPEND="${RDEPEND}"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir=/usr/$(get_libdir)
+		--libdir=/usr/$(get_libdir)/${PN}
+		--with-dynlib=/usr/$(get_libdir)
+		--with-lib=/usr/$(get_libdir)/skalibs
+		--with-sysdeps=/usr/$(get_libdir)/skalibs
+		--enable-shared
+		$(use_enable static allstatic)
+		$(use_enable static static-libc)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myconf[@]}"
+}