dev-libs/capstone: bump up to 4.0.1

Package-Manager: Portage-2.3.54, Repoman-2.3.12
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-libs/capstone/Manifest b/dev-libs/capstone/Manifest
index f3ffa497b093..66b9b56b6b42 100644
--- a/dev-libs/capstone/Manifest
+++ b/dev-libs/capstone/Manifest
@@ -1,2 +1,3 @@
 DIST capstone-3.0.5_rc2.tar.gz 2829338 BLAKE2B dd35fc6c31ec008f78840410ea0d20de56ea8f01c3af1d28488beaceee7fa06ce03c8cd0f56d834eb738d23f528d240693586122b9c1e353365f7348fb6f8362 SHA512 31bafdb0b3183d0c054a4244cc135db9a3c3dc5cb2e2af706bfede0d53cca8cba81d74b74ef9a4adbfd6c79cc408864dd80b8203791e17bd6c98bb69ea4f6894
+DIST capstone-4.0.1.tar.gz 3434276 BLAKE2B 585e0ee19b76d96116c67b021bbe19fd01d8db600b565094ff71a01d8a87b1123a8c5e2f944f1551c411565d5a25dfbfbb3138ca220b1281044a31004002399e SHA512 43c52024065b41b45eff9423341db3f3d5163fa7aa01b360faa30437786740c8f2c34c36faa04dced5308e09d8bd78df3bad0ab9c06f98612169edb176f83c36
 DIST capstone-4.0.tar.gz 3411532 BLAKE2B 3e60a946e81f6d6ea88c314ad066e1855e2401cd9e8e61a67d48071b0fe4b705b2276b0d2b52d0979f472895a69cbe7609f6a2c60b79be668730f41ea98bf92e SHA512 5a10c67e88b246ad905364c62c56b4741df242c22f1b62bdea171e4d1d43e484f42f30b33e17324be6cff4c6fb10365528a9c3f4b2a5339ad24b0564fdd40bdb
diff --git a/dev-libs/capstone/capstone-4.0.1.ebuild b/dev-libs/capstone/capstone-4.0.1.ebuild
new file mode 100644
index 000000000000..c0b0864f5e26
--- /dev/null
+++ b/dev-libs/capstone/capstone-4.0.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="disassembly/disassembler framework + bindings"
+HOMEPAGE="http://www.capstone-engine.org/"
+SRC_URI="https://github.com/aquynh/${PN}/archive/${PV/_rc/-rc}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/4" # libcapstone.so.4
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+IUSE="python"
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-FLAGS.patch
+	"${FILESDIR}"/${PN}-4.0-no-fuzz-tests.patch
+)
+
+S=${WORKDIR}/${P/_rc/-rc}
+
+wrap_python() {
+	if use python; then
+		pushd bindings/python >/dev/null || die
+		distutils-r1_${1} "$@"
+		popd >/dev/null
+	fi
+}
+
+src_prepare() {
+	default
+
+	wrap_python ${FUNCNAME}
+}
+
+src_configure() {
+	{
+		cat <<-EOF
+		# Gentoo overrides:
+		#   verbose build
+		V = 1
+		#   toolchain
+		AR = $(tc-getAR)
+		CC = $(tc-getCC)
+		RANLIB = $(tc-getRANLIB)
+		#  toolchain flags
+		CFLAGS = ${CFLAGS}
+		LDFLAGS = ${LDFLAGS}
+		#  libs
+		LIBDIRARCH = $(get_libdir)
+		EOF
+	} >> config.mk || die
+
+	wrap_python ${FUNCNAME}
+}
+
+src_compile() {
+	default
+
+	wrap_python ${FUNCNAME}
+}
+
+src_test() {
+	default
+
+	wrap_python ${FUNCNAME}
+}
+
+src_install() {
+	default
+
+	wrap_python ${FUNCNAME}
+}