dev-libs/keystone: add 0.9.2

Closes: https://bugs.gentoo.org/812563
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 88 insertions, 10 deletions

diff --git a/dev-libs/keystone/Manifest b/dev-libs/keystone/Manifest
index f661bedc4b73..406bb5c69582 100644
--- a/dev-libs/keystone/Manifest
+++ b/dev-libs/keystone/Manifest
@@ -1 +1,2 @@
 DIST keystone-0.9.1.tar.gz 4326151 BLAKE2B 2d41388f4beeff3c424386c77cb75eeca613c66f80e807035f709822f241ef74f64085260678772580cb82bcceda83b4b3c31b92393f8d70f24d54f77f7ba224 SHA512 3bd9c3793d5862a0a8628b52da381625e62445f661dbd5ed715723e7d9db01ce3f9586e5ca0a5cc71e8ceb6c912050f5c28e3ccd540e72c8abcfd2f0d1bbae17
+DIST keystone-0.9.2.tar.gz 4433222 BLAKE2B 5654ae6a66ccf6832fbdbb8c1083a2318e413bb833a0fadc4e1374f0de601e3dad9f354b1dec92d9a944621923458e432510299c1b55579ac9bb6b6e90a818de SHA512 5d4dd30410410bc7848e75a2e31e8ecef6241ad25e21963aa7a07bbea21d95b75e235c80573129014102684c9647710ace3c0776a8401844d7e4b45cab7bd04b
diff --git a/dev-libs/keystone/keystone-0.9.2.ebuild b/dev-libs/keystone/keystone-0.9.2.ebuild
new file mode 100644
index 000000000000..7ef25cfa1b43
--- /dev/null
+++ b/dev-libs/keystone/keystone-0.9.2.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LLVM_MAX_SLOT=12
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit cmake distutils-r1 llvm
+
+DESCRIPTION="assembly/assembler framework + bindings"
+HOMEPAGE="https://www.keystone-engine.org/"
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/keystone-engine/keystone.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/keystone-engine/keystone/archive/${PV/_rc/-rc}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+# Keep in sync with llvm/CMakeLists.txt, subset of sys-devel/llvm
+ALL_LLVM_TARGETS=( AArch64 ARM Hexagon Mips PowerPC Sparc SystemZ X86 )
+ALL_LLVM_TARGETS=( "${ALL_LLVM_TARGETS[@]/#/llvm_targets_}" )
+LLVM_TARGET_USEDEPS=${ALL_LLVM_TARGETS[@]/%/?}
+
+IUSE="python ${ALL_LLVM_TARGETS[*]}"
+
+RDEPEND="
+	<sys-devel/llvm-$((${LLVM_MAX_SLOT} + 1)):=[${LLVM_TARGET_USEDEPS// /,}]
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="
+	|| ( ${ALL_LLVM_TARGETS[*]} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+S=${WORKDIR}/${P/_rc/-rc}
+
+wrap_python() {
+	if use python; then
+		pushd bindings/python >/dev/null || die
+		distutils-r1_${1} "$@"
+		popd >/dev/null || die
+	fi
+}
+
+src_prepare() {
+	default
+	sed -i '/NOT uppercase_CMAKE_BUILD_TYPE MATCHES/ s/DEBUG/GENTOO|DEBUG/' \
+		llvm/CMakeLists.txt || die
+	cmake_src_prepare
+	wrap_python ${FUNCNAME}
+}
+
+src_configure() {
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DCMAKE_CONFIGURATION_TYPES="Gentoo"
+		-DLLVM_LIBDIR_SUFFIX=${libdir#lib}
+		-DBUILD_SHARED_LIBS=ON
+		-DLLVM_TARGETS_TO_BUILD="${LLVM_TARGETS// /;}"
+		-DLLVM_HOST_TRIPLE="${CHOST}"
+	)
+
+	cmake_src_configure
+	wrap_python ${FUNCNAME}
+}
+
+src_compile() {
+	cmake_src_compile
+	wrap_python ${FUNCNAME}
+}
+
+src_install() {
+	cmake_src_install
+	wrap_python ${FUNCNAME}
+}
diff --git a/dev-libs/keystone/keystone-9999.ebuild b/dev-libs/keystone/keystone-9999.ebuild
index 7a76969465cf..7ef25cfa1b43 100644
--- a/dev-libs/keystone/keystone-9999.ebuild
+++ b/dev-libs/keystone/keystone-9999.ebuild
@@ -3,8 +3,9 @@
 
 EAPI=7
 
+LLVM_MAX_SLOT=12
 DISTUTILS_OPTIONAL=1
-PYTHON_COMPAT=( python3_{7,8} )
+PYTHON_COMPAT=( python3_{8,9,10} )
 
 inherit cmake distutils-r1 llvm
 
@@ -29,18 +30,10 @@ LLVM_TARGET_USEDEPS=${ALL_LLVM_TARGETS[@]/%/?}
 
 IUSE="python ${ALL_LLVM_TARGETS[*]}"
 
-LLVM_MAX_SLOT=10
-
 RDEPEND="
-	<sys-devel/llvm-11:=
-	|| (
-		sys-devel/llvm:8[${LLVM_TARGET_USEDEPS// /,}]
-		sys-devel/llvm:9[${LLVM_TARGET_USEDEPS// /,}]
-		sys-devel/llvm:10[${LLVM_TARGET_USEDEPS// /,}]
-	)
+	<sys-devel/llvm-$((${LLVM_MAX_SLOT} + 1)):=[${LLVM_TARGET_USEDEPS// /,}]
 	python? ( ${PYTHON_DEPS} )
 "
-
 DEPEND="${RDEPEND}"
 
 REQUIRED_USE="