dev-libs/libinput: Bump to version 1.16.5

Package-Manager: Portage-3.0.16, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index c1b4a613dde6..764662712e70 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1,2 +1,3 @@
 DIST libinput-1.16.4.tar.xz 596028 BLAKE2B ad2160d83bcbdd65383272e0c4b35e35c7b46a6d0c771d7c0188c92b204d57dae73d0820bb93f662f155c1eab19c0195110f5a18a68de890c808925d5c056814 SHA512 a95a3bcf58a9298946d15f4f2fd93dc5807d3042f8797950a1ffd96d3c979b55a764f035a9f7680d0ea400b033698c322eb61a4387dbc280db6110ffd3e137ee
+DIST libinput-1.16.5.tar.xz 595000 BLAKE2B c325aac47a73992232cf7905935bb6ef0ace89d6e4e8d64feff3fcdde3aa9acb6c1470a07cc89430bfecf52df62a37617ced1cf5f05435eefa1902ee85e20a0e SHA512 b2fdd87375cbd5b212f76cefedfaa146966dde1d5e5d566beadd3167749dc3667214946178b157fa4b44360dc6b86a25ffb0356049cdf5a57d0fa2b8e3fcb1e9
 DIST libinput-1.17.0.tar.xz 612004 BLAKE2B 035b85115917804c032a4b0629b4cfee29513beff6cf84921d95d3f9d09d5f55574e1088256f72e271dbb6508b66c6a7271cf07be572a402e6c9ef02f075591f SHA512 490c7e59cbaa43e4190dbc421582dca887b6ae92304c4f8f3ea9df515bd76de41ca9a376e6f1cfe7b235dd2d5d8d8ef5982f5ddcf958e3b31b981e9440bb0888
diff --git a/dev-libs/libinput/libinput-1.16.5.ebuild b/dev-libs/libinput/libinput-1.16.5.ebuild
new file mode 100644
index 000000000000..610b570961f9
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.16.5.ebuild
@@ -0,0 +1,88 @@
+# Copyright 2014-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? ( dev-util/valgrind )
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+	>=dev-libs/libevdev-1.3
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-libs/check-0.9.10 )"
+
+python_check_deps() {
+	has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+	has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	pkgname="dev-python/python-libevdev"
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "${pkgname}" ; then
+		einfo "${pkgname} must be installed to use the"
+		einfo "libinput measure and libinput replay tools."
+	fi
+
+	udevadm hwdb --update --root="${ROOT}"
+}