dev-libs/protobuf-c: Bump to version 1.3.2

Package-Manager: Portage-2.3.72, Repoman-2.3.17
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-libs/protobuf-c/protobuf-c-1.3.2.ebuild b/dev-libs/protobuf-c/protobuf-c-1.3.2.ebuild
new file mode 100644
index 000000000000..e666446a3b08
--- /dev/null
+++ b/dev-libs/protobuf-c/protobuf-c-1.3.2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+MY_PV="${PV/_/-}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Protocol Buffers implementation in C"
+HOMEPAGE="https://github.com/protobuf-c/protobuf-c"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${MY_PV}/${MY_P}.tar.gz"
+
+LICENSE="BSD-2"
+# Subslot == SONAME version
+SLOT="0/1.0.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="static-libs test"
+
+BDEPEND="dev-libs/protobuf:0
+	virtual/pkgconfig[${MULTILIB_USEDEP}]"
+DEPEND="dev-libs/protobuf:0=[${MULTILIB_USEDEP}]"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	if ! use test; then
+		eapply "${FILESDIR}"/${PN}-1.3.0-no-build-tests.patch
+	fi
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}