dev-libs/rapidjson: Correct DOC and LIB dirs, https homepage, EAPI=7

Closes: https://bugs.gentoo.org/696978
Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Craig Andrews <candrews@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-libs/rapidjson/rapidjson-1.1.0-r2.ebuild b/dev-libs/rapidjson/rapidjson-1.1.0-r2.ebuild
new file mode 100644
index 000000000000..bd6b5e3e3671
--- /dev/null
+++ b/dev-libs/rapidjson/rapidjson-1.1.0-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="A fast JSON parser/generator for C++ with both SAX/DOM style API"
+HOMEPAGE="https://rapidjson.org/"
+
+LICENSE="MIT"
+IUSE="doc examples test"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/miloyip/rapidjson.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/miloyip/rapidjson/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/rapidjson-${PV}"
+fi
+
+DEPEND="
+	doc? ( app-doc/doxygen )
+	test? (
+		dev-cpp/gtest
+		dev-util/valgrind
+	)"
+RDEPEND=""
+
+PATCHES=(
+	"${FILESDIR}/${P}-gcc-7.patch"
+)
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -i -e 's|-Werror||g' CMakeLists.txt || die
+	sed -i -e 's|-Werror||g' example/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOC_INSTALL_DIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DLIB_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)"
+		-DRAPIDJSON_BUILD_DOC=$(usex doc)
+		-DRAPIDJSON_BUILD_EXAMPLES=$(usex examples)
+		-DRAPIDJSON_BUILD_TESTS=$(usex test)
+		-DRAPIDJSON_BUILD_THIRDPARTY_GTEST=OFF
+	)
+	cmake-utils_src_configure
+}