dev-python/django: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 105 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 30c0fd19297b..3063334a06b2 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,8 +4,6 @@ DIST Django-2.2.17.tar.gz 8885492 BLAKE2B 30046adc54c31e0e8dac3c573da58e8536246b
 DIST Django-3.0.10.tar.gz 8958332 BLAKE2B 0ff17da9d9175b080d81e334e46ec6daaec5e4cd48f5d9a614c84b448a6d4b93d304b3fd25bcee665d65f589a8f94cf83f002bbd7a27975d23e3516286784e01 SHA512 fcce2815f966a5eb0f7986c16d065b352c73ea2ea4fc1422d440487d84162c5a93aa45b9173ba5d62d6caee2e976a9ac818f228b47ed7f4f50deda27bac995e9
 DIST Django-3.0.11.checksum.txt 2438 BLAKE2B df936992a02e5a34b26e91654962507d973f8831c1eebada4cbdb578f83fba974532867b9f20828afc2467c2521e117b8dd543cde6f664d3c122a95207c50608 SHA512 a7b98d102775cc7854b0c242507d4ff8778984dc8b2e269352103249d6d1c5cea7e6eb8dbe08700b19ad4428e30c469e0e959a622ea4ce3198a75f72b2bb8871
 DIST Django-3.0.11.tar.gz 8958879 BLAKE2B 078ffde9ae186ae8add2136c303ba38a1b38525481b2272384b8a1bb3428dcf6a31991a86b2078aea6cf250808af399acac5461a33c8e1fda5d6bc552eac478f SHA512 d24e8167f3f871f24ea5e288557a49d71f9b5c398c84e8434d5d3dc224ef62775121a016ad89e997fabe88893adc3a83176211d5b9a9730ec23d37d256aa4fb0
-DIST Django-3.1.3.checksum.txt 2429 BLAKE2B 7184da75a1da2c615c78a892c8331ff4abfec86e1ae93f8a74c836988d97ecafbbadaecffd352904c01b40a840a80f4d24e8b48f2570054a2349ef6c58bb43e3 SHA512 ecb1de139b05e697253e0b09fd15b692050be647cceb30d8f1482613d0c3393a3017460aabd7ff71ad1de2a8c70cc9276525d7a2a9285540a052805c969f55d8
-DIST Django-3.1.3.tar.gz 9253273 BLAKE2B 9284b637ea39e028ebabe44de50dacfe6a89621fcc5eea73b7f470fc998faeb361da428be8f3f3e349f25b8629b5a350f3a5b7c35ea50183b285daf63d8944a7 SHA512 0f49316dc61a299a257313c27051852e948337491047bacb2221c9c753a5cf4bafb2ed686311ad5345dd3045260331afccb013c21503891538340225a469d1ad
 DIST Django-3.1.4.checksum.txt 2466 BLAKE2B 635ddd40b542890aef29f53df0fad172e48450081f57c72042a71bb5de654b1d1f5f7ce0c588b1070a203e1d4afe3a1ed19431dd23a2a67cd510d4072c79a00f SHA512 729b771008489bbf0563002e438ef88abb2a14b2c29f307cb2db9c75450f30ac8bd4920bf0493dbec06b3640fc0d4b6817e8a054af1028ad065bd321c761a6c3
 DIST Django-3.1.4.tar.gz 9392125 BLAKE2B b583442de50c358e70a49b9ef557d43211e6faee17933a44012dbb9f0dac3ccbf0a91e01a2b8b798fff7ae05100199e9e9c94a81748b41ea13e49d12bb510617 SHA512 02cfaabb25e5f932dcbf659faba2f0afe298e4bee4f510f7adebfff181bdd13c3a0b08e8ce379bcc59326d904be8699db4ce31065d93566b93cad758365207f5
 DIST Django-3.1.5.checksum.txt 2428 BLAKE2B 69347177b3c8c592a0b9df832c8f0abebdd4f1ff420f95f63310eb41d3614b241dc8f01b71abfec12faa006a8e69310d31cd68425f57ecf7a02948e83c65e0b3 SHA512 93d3e0de057518b60d9da2c1193ec59a8601f53b5d81a09fa4f6866336fbff85b81c01711eb07544fce30fe17e6dec89e5a5d6a66a929d451bca77cfe172bf19
diff --git a/dev-python/django/django-3.1.3.ebuild b/dev-python/django/django-3.1.3.ebuild
deleted file mode 100644
index b13337e7cee7..000000000000
--- a/dev-python/django/django-3.1.3.ebuild
+++ /dev/null
@@ -1,103 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DISTUTILS_USE_SETUPTOOLS=rdepend
-PYTHON_COMPAT=( python3_{6..9} )
-PYTHON_REQ_USE='sqlite?,threads(+)'
-
-inherit bash-completion-r1 distutils-r1 optfeature verify-sig
-
-MY_P=${P^}
-DESCRIPTION="High-level Python web framework"
-HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
-SRC_URI="
-	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
-	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="BSD"
-# admin fonts: Roboto (media-fonts/roboto)
-LICENSE+=" Apache-2.0"
-# admin icons, jquery, xregexp.js
-LICENSE+=" MIT"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 ~ppc ~ppc64 x86 ~x64-macos"
-IUSE="doc sqlite test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/asgiref[${PYTHON_USEDEP}]
-	dev-python/pytz[${PYTHON_USEDEP}]
-	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
-BDEPEND="
-	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
-	test? (
-		$(python_gen_impl_dep sqlite)
-		${RDEPEND}
-		dev-python/docutils[${PYTHON_USEDEP}]
-		dev-python/jinja[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/pillow[webp,${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		dev-python/selenium[${PYTHON_USEDEP}]
-		dev-python/tblib[${PYTHON_USEDEP}]
-		sys-devel/gettext
-	)
-	verify-sig? ( app-crypt/openpgp-keys-django )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
-	"${FILESDIR}"/django-gettext-0.21.patch
-)
-
-distutils_enable_sphinx docs --no-autodoc
-
-VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
-
-src_unpack() {
-	if use verify-sig; then
-		cd "${DISTDIR}" || die
-		verify-sig_verify_signed_checksums \
-			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
-		cd "${WORKDIR}" || die
-	fi
-
-	default
-}
-
-src_prepare() {
-	# do not bind to a specific version
-	# https://bugs.gentoo.org/750695
-	sed -i -e 's:asgiref ~= 3.2.10:asgiref:' setup.cfg || die
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	# Tests have non-standard assumptions about PYTHONPATH,
-	# and don't work with ${BUILD_DIR}/lib.
-	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
-		die "Tests fail with ${EPYTHON}"
-}
-
-python_install_all() {
-	newbashcomp extras/django_bash_completion ${PN}-admin
-	bashcomp_alias ${PN}-admin django-admin.py
-
-	distutils-r1_python_install_all
-}
-
-pkg_postinst() {
-	elog "Additional Backend support can be enabled via"
-	optfeature "MySQL backend support" dev-python/mysqlclient
-	optfeature "PostgreSQL backend support" dev-python/psycopg:2
-	elog
-	elog "Other features can be enhanced by"
-	optfeature "GEO Django" "sci-libs/gdal[geos]"
-	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
-	optfeature "ImageField Support" dev-python/pillow
-	optfeature "Password encryption" dev-python/bcrypt
-	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
-}