dev-python/eventlet: 0.25.0 bump

Package-Manager: Portage-2.3.66, Repoman-2.3.16
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/eventlet/Manifest b/dev-python/eventlet/Manifest
index f298d782f445..abf9cfb45663 100644
--- a/dev-python/eventlet/Manifest
+++ b/dev-python/eventlet/Manifest
@@ -3,3 +3,4 @@ DIST eventlet-0.20.0.tar.gz 466828 BLAKE2B 43beb8f924c5e375a554db3fb90e3c39121ff
 DIST eventlet-0.20.1.tar.gz 469509 BLAKE2B 727844b70c4e1874a58efc95551dd7f12bec1c8d01cadeaedbc49f00a86e1393b690076fe720e8efdf00107f72b892a3a1f4c4921f95656b904221e748df7f09 SHA512 875c1ca82822a486bf28866c7d1f34df2419e7d33450a21740434d2e7f15c37a1090436cb7fe1feaeb5c810d39e4b238206c502323317897c8a42e844cbe7734
 DIST eventlet-0.21.0.tar.gz 484191 BLAKE2B 07d3f5d1dca11032d51fef9ceb624e07da9e93bed914233da9abbdff27f21f2482b9e3417b50a63f383cae13615c6a781104a05dfb66f28d6ab4e469bce06ef9 SHA512 4ee682ca8faf870ff6f1d72e93527028f73ae13d7f755eceafb23f3cde48e52b83ff04b645b7e90299997713de93c52f244db8b81d6abc7788a56ea38c7b0f47
 DIST eventlet-0.24.1.tar.gz 391579 BLAKE2B f8abfe6d18ed3b2edf4b2fa3d197abdd1e9029dd10c035427a2ddcb70cdaa76da114083ce7016af7151927fcb2f93ce6ffa0417dbe1a125948318baaed2f6184 SHA512 867f8ead3a6c0dd692c5cc5d9f1181b04456bdb270ea95d84f7f97da4603b333df539721cda002437c035fac51134bee8cc3495e09b6a25ae1c46fdaf015d0c3
+DIST eventlet-0.25.0.tar.gz 392105 BLAKE2B f528434dadfc15ce91b7842c47d1942963c430758483e56c756267f71910310e5ed6bc8b76cf3e8a9e3421c016776cf5afab6b675e49aaa4420685aee8c8b999 SHA512 f42549ecc6ca6833d611dc178593e69ff0d63881111fe7f9357b26c602a57dccbbc53101b86ed01e1e2b4a201afa8d170ade1052fcec36aab8776c56a8a15b42
diff --git a/dev-python/eventlet/eventlet-0.25.0.ebuild b/dev-python/eventlet/eventlet-0.25.0.ebuild
new file mode 100644
index 000000000000..ccae643ba72d
--- /dev/null
+++ b/dev-python/eventlet/eventlet-0.25.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Highly concurrent networking library"
+HOMEPAGE="https://pypi.org/project/eventlet/ https://github.com/eventlet/eventlet/"
+SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/dnspython-1.15.0[${PYTHON_USEDEP}]
+	virtual/python-enum34[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3[${PYTHON_USEDEP}]
+	>=dev-python/monotonic-1.4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]"
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/python-docs-2.7.6-r1:2.7 )
+	test? ( ${RDEPEND}
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# provided by virtual/python-enum34
+	sed -i '/enum-compat/d' setup.py || die
+
+	if use doc; then
+		local PYTHON_DOC_ATOM=$(best_version -b dev-python/python-docs:2.7)
+		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
+		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
+		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
+		sed -i "s|'https://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" doc/conf.py || die
+	fi
+
+	if use test; then
+#		sed -i '/This is a Python 3 module/d' eventlet/green/http/__init__.py || die
+#		sed -i 's/^import/from OpenSSL import/g' eventlet/green/OpenSSL/__init__.py || die
+#		sed -i 's/^from version/from OpenSSL.version/' eventlet/green/OpenSSL/__init__.py || die
+		sed -i 's/TEST_TIMEOUT = 1/TEST_TIMEOUT = 10/' tests/__init__.py || die
+	fi
+
+	# Prevent file collisions from teestsuite
+	sed -e "s:'tests', :'tests', 'tests.*', :" -i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# https://github.com/eventlet/eventlet/issues/152
+	use doc && emake -C doc html
+}
+
+python_test() {
+	# Several errors 1 failure
+	# https://github.com/eventlet/eventlet/issues/151
+	nosetests tests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}