dev-python/flit: add 3.8.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-python/flit/flit-3.8.0.ebuild b/dev-python/flit/flit-3.8.0.ebuild
new file mode 100644
index 000000000000..a2c1e11caabf
--- /dev/null
+++ b/dev-python/flit/flit-3.8.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Simplified packaging of Python modules"
+HOMEPAGE="https://github.com/pypa/flit https://flit.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~x86"
+
+RDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	>=dev-python/flit_core-${PV}[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests_download[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	sys-apps/grep
+	test? (
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# requires Internet
+	tests/test_config.py::test_invalid_classifier
+	# failing due to Gentoo pip patches
+	tests/test_install.py::InstallTests::test_install_data_dir
+	tests/test_install.py::InstallTests::test_install_module_pep621
+	tests/test_install.py::InstallTests::test_symlink_data_dir
+	tests/test_install.py::InstallTests::test_symlink_module_pep621
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/pygments-github-lexers \
+	dev-python/sphinx_rtd_theme
+
+src_prepare() {
+	# make sure system install is used
+	rm -r flit_core || die
+	distutils-r1_src_prepare
+}