dev-python/hatchling: Bump to 1.21.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index e9031a1342fd..268b01eb27d1 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -2,3 +2,4 @@ DIST hatch-hatchling-v1.18.0.gh.tar.gz 386992 BLAKE2B 9597d139ca0d59b82862a4b892
 DIST hatch-hatchling-v1.19.0.gh.tar.gz 601176 BLAKE2B 1625e8a3da1158328c5aba5fbec6282cd6603ad34ed48ec4fd2ca3e5bd79141f4bb98f631d50cf9796fb1cbbd1274e4948d0a535a65499f7d0209111c323f043 SHA512 eacbe002e5905468c4374c72dd53fdc5ab4b22d8ea0ce6ca56a12c6bf97b67d5d711dbbaa85cf1a11995fac9fe42c99cf870cb6a46705ea738081ec689ac6468
 DIST hatch-hatchling-v1.19.1.gh.tar.gz 761441 BLAKE2B 622cf0c799758506c2f13840103d886e739dade12362bd21bd8c6336f5bb7da235517b94cfece8835e5dd476dbac7f035a77b055ca0e11f2cee513572fc9a20e SHA512 4ccc857771fa7d0aad05e8023b4f7c021dd919d92385e23684261f83d6323149f1b347900ddbe664af97d377e329f6ea3a8ad011b1834057a699186743493e08
 DIST hatch-hatchling-v1.20.0.gh.tar.gz 761937 BLAKE2B 7e413a98d21fde46676ecb4264875f6addcd18efcf73d208cfb2ce36bc07ff7889c5a0884ac9f0c1537801f7ac6ec73f0fc74f18ca202b2b4d8ee13328ee912a SHA512 5b4c31825238fa21002fb72fea726a4bd2f16d39f1b4026506ab662df20a03e49eff912d39c34091335aeea448bf2a1b07e6a1d723a26a16794792ed0b17f2b1
+DIST hatch-hatchling-v1.21.0.gh.tar.gz 764748 BLAKE2B 3b048ed34df4da9ed5ec8d1c0121e21aabada559e981e9fd36a7188aceedf79594b165ed705edfbc5d210a09ee9a022c8c6e433e930338f2053e4c48feef0d44 SHA512 5ee8151929d6bdbb67e7f4e3e0298c730ff7fef5a7d7b764192eb2e16327d80a2935eee8831c168d19ed41c7184ca5b5eef7a67c9d5756cea25a7bd79945d344
diff --git a/dev-python/hatchling/hatchling-1.21.0.ebuild b/dev-python/hatchling/hatchling-1.21.0.ebuild
new file mode 100644
index 000000000000..f041834d0884
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.21.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{10..12} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+# deps are listed in backend/src/hatchling/ouroboros.py
+RDEPEND="
+	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/trove-classifiers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+		# broken if CARGO is set
+		tests/backend/builders/test_app.py::TestBuildBootstrap::test_no_cargo
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	# sigh; standalone test suites are overrated, right?
+	echo "__version__ = '${PV}'" > src/hatch/_version.py || die
+	# tests mock cargo subprocess call but the backend raises if CARGO
+	# is not set and shutil.which() can't find it
+	local -x CARGO=cargo
+	epytest tests/backend
+}