dev-python/keyring: 18.0.1 bump with cleanup of 18.0.0

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/keyring/keyring-18.0.1.ebuild b/dev-python/keyring/keyring-18.0.1.ebuild
new file mode 100644
index 000000000000..8dbccefd2219
--- /dev/null
+++ b/dev-python/keyring/keyring-18.0.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Provides access to the system keyring service"
+HOMEPAGE="https://github.com/jaraco/keyring"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="PSF-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/secretstorage[${PYTHON_USEDEP}]
+	dev-python/entrypoints[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/pytest-3.7.4[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	# Skip an interactive test
+	pytest -vv --override-ini="addopts=--doctest-modules" \
+		--ignore ${PN}/tests/backends/test_kwallet.py \
+		|| die "testsuite failed under ${EPYTHON}"
+}