dev-python/moto: Bump to 2.0.8

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index f324c0db9f8f..2755f57c2182 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -6,3 +6,4 @@ DIST moto-2.0.2.tar.gz 1534459 BLAKE2B b4609f332e8f8eb8d61250919eca805f82a6dfc46
 DIST moto-2.0.5.tar.gz 1551415 BLAKE2B 452cb94443188e1715145bee574f04924d894a3d647673443a8a335bb907f8601098540b032d6c9a8ced3e1fc490c49ad70c877547d905cece05bbb742d05976 SHA512 70e64ab98873d480e776a2139a4d351665c6c2f98faf90e2871c6b9998571d1bd239757bc90bbc6ab6e1ed510598bfce77157ad522953efe40c884068885c57d
 DIST moto-2.0.6.tar.gz 1557871 BLAKE2B dd4c23758bc9c98fbd2b2a70af744daa245fc8b4b1154348486ae85d195e5e3fa2c513f61386504d05c0d646e81fbf8ec5bf41be317b9fd7581668cd23cc1db3 SHA512 9f287ff07f948dd3d2d6af1c6120d29e9625e420bb94f83c230d813e26689161f9a2e89e2b32947e82084cdcd865fef714ad14309ff41371bd37d251481f8dc9
 DIST moto-2.0.7.tar.gz 1565849 BLAKE2B 1c6491828a43156fd347bcce80f3440cd8d4964e28bab19593e29fd88aed558652b08c81c577312f9c612adc666ddd35fdd46b4d2d8fb82eef380210e9c62d8d SHA512 5df26f478909c57d4ba76bb7c6e002c37d7f604084c157744be32da93dbb705605a7a85eb0774cbf2c0083f7096f01075ddb1a119cb7ac2f3931cf58896f1629
+DIST moto-2.0.8.tar.gz 1569426 BLAKE2B 746313241d49558ab49d7e2116406f128a315a9fca40956808e7f901e91518551a1f75c95c9ce5c92534221d1db3e01a3baa2cef6cadab9a9d024cc30d8ce0e2 SHA512 5cf1a47c97100b76ad9b69787ce4df00f24f93ba1a36a242cea535ede649af457ff043b44f1cce4a4e44b6735844652f69271f18edac0748b636f4e519545018
diff --git a/dev-python/moto/moto-2.0.8.ebuild b/dev-python/moto/moto-2.0.8.ebuild
new file mode 100644
index 000000000000..7c3740bdf84d
--- /dev/null
+++ b/dev-python/moto/moto-2.0.8.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-tempfile[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/boto[${PYTHON_USEDEP}]
+	dev-python/cfn-python-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	dev-python/dicttoxml[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.9.201[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.12.201[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# unping indirect dep on ecdsa that's supposed to workaround pip
+	# bugs
+	sed -i -e '/ecdsa/s:<0.15::' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# pytest-django causes freezegun try to mangle stuff inside django
+	# which fails when django is not really used
+	epytest -p no:django -m 'not network'
+}