dev-python/pikepdf: Bump to 9.5.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index 16eeafacc2fb..ca78d08adf8d 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -2,3 +2,4 @@ DIST pikepdf-9.1.1.tar.gz 2869514 BLAKE2B b196a61d599db1355695d40ac69e09ea7a020c
 DIST pikepdf-9.4.2.tar.gz 2914992 BLAKE2B daed44bd1106dbeadef449160e2ba5b389a1eeb7b23a32124a59b7861c1584d49feca01d6f54a18dc53eaace7823b23f62c1240c58445eb382ee25133b2d463b SHA512 2dc84672941a283da5486b2664252b6cd0612d7d2f9e8d10e3ae41f494be89821431568872b6b60045ffb2f1f687cea055093229ee443997997a8fae56e43e0b
 DIST pikepdf-9.5.0.tar.gz 2916148 BLAKE2B ad6d15fe9a6b9e44a4e1f6486a2e060311155292413453d99c52cf2d98f0fe7fdec823cc472282be5efaed7ccd3ad674cb5a5da8caab622d0f740e93b8ea5cc0 SHA512 6b73343fc6f93168059c106aa344b73f483802a2d222fbd5d16daffebe87c887ad2d757874856f4c6f776c39f78b3fe33e985abba80f0318cc65e69aaa369143
 DIST pikepdf-9.5.1.tar.gz 2916260 BLAKE2B ad665a237cc107895cdbca51f13fa4fdee2552449ccbed45dd478e0d1c291e9500f6d3a7138caad6aab4cb68b3f92cda042151f7ccfce9cb455b0eb9724e1ea0 SHA512 73e7f150439a64791b5ab3ca3f831c9cdef356343fa6985016690b3bff54b2cef169a7d223e66dc5e012467dbc969295e5355a01311de0aaf09a0c625c963246
+DIST pikepdf-9.5.2.tar.gz 2916549 BLAKE2B 821fe21cb2ef471ab7313e2dab371f0a5290659225647ca4059995af9112e4f5425e0a9e11f9691dc2da9786beeffb2abc33ec374bb97b3fe1f25bd6feba042a SHA512 ac7c33c7cd23e34eb1bd518aae7167285cca6cc710e37f05cac03512666777848a2ad3d17a72654832564a8521e69ea0d124c70c61aca0bed7123475bf03a359
diff --git a/dev-python/pikepdf/pikepdf-9.5.2.ebuild b/dev-python/pikepdf/pikepdf-9.5.2.ebuild
new file mode 100644
index 000000000000..3bd9cbda965f
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-9.5.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="big-endian"
+
+# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
+# https://qpdf.readthedocs.io/en/stable/release-notes.html.
+DEPEND="
+	>=app-text/qpdf-11.5.0:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecated[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-10.0.1[lcms,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.12.0[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+		!big-endian? (
+			>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		)
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.10)
+		media-libs/tiff[zlib]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -e '/-n auto/d' -i pyproject.toml || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile to system load
+		tests/test_image_access.py::test_random_image
+		tests/test_image_access.py::test_image_save_compare
+		tests/test_image_access.py::test_palette_nonrgb
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p timeout
+}