dev-python/pyftpdlib: bump to 1.5.4, drop pypy and some arches.

Add missing sphinx dependency for doc build, disable intersphinx.

Package-Manager: Portage-2.3.31, Repoman-2.3.9
RepoMan-Options: --force
Closes: https://github.com/gentoo/gentoo/pull/8363

1 files changed, 68 insertions, 0 deletions

diff --git a/dev-python/pyftpdlib/pyftpdlib-1.5.4.ebuild b/dev-python/pyftpdlib/pyftpdlib-1.5.4.ebuild
new file mode 100644
index 000000000000..bc5c598d7193
--- /dev/null
+++ b/dev-python/pyftpdlib/pyftpdlib-1.5.4.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python FTP server library"
+HOMEPAGE="https://github.com/giampaolo/pyftpdlib https://pypi.org/project/pyftpdlib/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~m68k ~mips ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
+IUSE="doc examples ssl test"
+
+RDEPEND="
+	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pysendfile[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	sed -i "s/'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	"${EPYTHON}" ${PN}/test/runner.py || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r demo/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] && \
+		[[ ${PYTHON_TARGETS} == *python2_7* ]] && \
+		! has_version dev-python/pysendfile ; then
+		elog "dev-python/pysendfile is not installed"
+		elog "It can considerably speed up file transfers for Python 2"
+	fi
+}