dev-python/pymediainfo: bump to 2.3.0, update dependencies

dev-python/setuptools_scm is now required at build time and
dev-python/setuptools at runtime to obtain the package version.

Package-Manager: Portage-2.3.31, Repoman-2.3.9

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/pymediainfo/pymediainfo-2.3.0.ebuild b/dev-python/pymediainfo/pymediainfo-2.3.0.ebuild
new file mode 100644
index 000000000000..cc3c9dec3824
--- /dev/null
+++ b/dev-python/pymediainfo/pymediainfo-2.3.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="A wrapper around the mediainfo library"
+HOMEPAGE="https://github.com/sbraz/pymediainfo"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	media-libs/libmediainfo
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	# requires network access
+	py.test tests/test_pymediainfo.py -k "not MediaInfoURLTest" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}