dev-python/pypy3-exe-bin: Bump to 7.3.8_rc1 (PyPy3.9!)

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.8_rc1.ebuild b/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.8_rc1.ebuild
new file mode 100644
index 000000000000..d55bb03c5536
--- /dev/null
+++ b/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.8_rc1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit pax-utils
+
+MY_P=pypy3-exe-${PV}-1
+DESCRIPTION="PyPy3 executable (pre-built version)"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/pypy/dev-python/pypy3-exe/${MY_P}.xpak
+			-> ${MY_P}.amd64.xpak
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/pypy/dev-python/pypy3-exe/${MY_P}.xpak
+			-> ${MY_P}.x86.xpak
+	)"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="3.9-${PV%_p*}"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=sys-libs/zlib-1.1.3:0/1
+	|| (
+		dev-libs/libffi-compat:7
+		dev-libs/libffi:0/7
+	)
+	virtual/libintl:0/0
+	dev-libs/expat:0/0
+	app-arch/bzip2:0/1
+	sys-libs/ncurses:0/6
+	!dev-python/pypy-exe:${SLOT}"
+
+PYPY_PV=${PV%_p*}
+QA_PREBUILT="
+	usr/bin/pypy3.9-c-${PYPY_PV}"
+
+src_unpack() {
+	ebegin "Unpacking ${MY_P}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${MY_P}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${MY_P} failed"
+}
+
+src_install() {
+	insinto /
+	doins -r usr
+	fperms +x "/usr/bin/pypy3.9-c-${PYPY_PV}"
+	pax-mark m "${ED}/usr/bin/pypy3.9-c-${PYPY_PV}"
+}