dev-python/sympy: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 107 deletions

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index 5730bd3ad453..9b42f9be6868 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1,2 +1 @@
-DIST sympy-1.13.1.gh.tar.gz 8130206 BLAKE2B 92ecaccddc5e48ac8e338488ff67cd0b6fdd9b40105334a82fc81c2ae4e6162a369ce142c6a61041698378d2c08eb5f95595702c35219a90d797485176f6fb23 SHA512 3e742ec74b6f774660a43b93c8b8a14ad97fbcf998c2ce15a6512ced5003804f4dec34f8beb3ad1f45f0f0a701110d1a81d6855075db03436cc77c101b33d7ea
 DIST sympy-1.13.2.gh.tar.gz 8141028 BLAKE2B 7a51fa75f1733364d467b79174b71ba866751399d311212144fdc3abdc8cea99618baf0b0fe3f2fe4cb9ab7153ecae4fe4bf00716e97ea4466637633f5618089 SHA512 87f7da425ed577e78392671cb635c99a11f3d6431b8c49a41611f4d2be5da1cadd8d07e0e684f2674792a2ee750b4031baec53156e7192d4c47714d4537c3222
diff --git a/dev-python/sympy/sympy-1.13.1.ebuild b/dev-python/sympy/sympy-1.13.1.ebuild
deleted file mode 100644
index a178ec16d6e5..000000000000
--- a/dev-python/sympy/sympy-1.13.1.ebuild
+++ /dev/null
@@ -1,106 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( pypy3 python3_{10..13} )
-
-inherit distutils-r1 virtualx
-
-DESCRIPTION="Computer Algebra System in pure Python"
-HOMEPAGE="
-	https://www.sympy.org/
-	https://github.com/sympy/sympy/
-	https://pypi.org/project/sympy/
-"
-# pypi sdist misses some files, notably top-level conftest.py, as of 1.12.1_rc1
-SRC_URI="
-	https://github.com/sympy/sympy/archive/${PV/_/}.tar.gz
-		-> ${P/_/}.gh.tar.gz
-"
-S=${WORKDIR}/${P/_/}
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
-IUSE="examples imaging ipython latex mathml opengl pdf png pyglet symengine texmacs"
-
-RDEPEND="
-	>=dev-python/mpmath-1.1.0[${PYTHON_USEDEP}]
-	dev-python/pexpect[${PYTHON_USEDEP}]
-	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
-	ipython? (
-		dev-python/ipython[${PYTHON_USEDEP}]
-	)
-	latex? (
-		virtual/latex-base
-		dev-texlive/texlive-fontsextra
-		png? ( app-text/dvipng )
-		pdf? ( app-text/ghostscript-gpl )
-	)
-	mathml? ( dev-python/lxml[${PYTHON_USEDEP}] )
-	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
-	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
-	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
-	texmacs? ( app-office/texmacs )
-"
-BDEPEND="
-	test? (
-		dev-python/hypothesis[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# require old version of antlr4
-		sympy/parsing/tests/test_autolev.py
-		sympy/parsing/tests/test_latex.py
-		# crash due to assertions in sys-devel/llvm[debug]
-		sympy/parsing/tests/test_c_parser.py
-
-		# TODO: pytest?
-		sympy/solvers/ode/tests/test_systems.py::test_linear_3eq_order1_type4_long_check
-		sympy/solvers/ode/tests/test_systems.py::test_linear_3eq_order1_type4_long_dsolve_dotprodsimp
-
-		# either very slow or hanging
-		sympy/solvers/ode/tests/test_systems.py::test_linear_new_order1_type2_de_lorentz_slow_check
-		sympy/integrals/tests/test_failing_integrals.py::test_issue_15227
-		sympy/matrices/tests/test_matrices.py::test_pinv_rank_deficient_when_diagonalization_fails
-		sympy/solvers/ode/tests/test_systems.py::test_nonlinear_3eq_order1_type1
-		sympy/solvers/ode/tests/test_systems.py::test_nonlinear_3eq_order1_type3
-
-		# known broken
-		# https://github.com/sympy/sympy/issues/26321
-		sympy/solvers/tests/test_simplex.py::test_lp
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	nonfatal epytest --veryquickcheck ||
-		die -n "Tests failed with ${EPYTHON}"
-}
-
-python_install_all() {
-	local DOCS=( AUTHORS README.md )
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-
-	distutils-r1_python_install_all
-
-	if use texmacs; then
-		exeinto /usr/libexec/TeXmacs/bin/
-		doexe data/TeXmacs/bin/tm_sympy
-		insinto /usr/share/TeXmacs/plugins/sympy/
-		doins -r data/TeXmacs/progs
-	fi
-}