Move dev-python/{text → textX}

Signed-off-by: Michał Górny <mgorny@gentoo.org>

4 files changed, 103 insertions, 0 deletions

diff --git a/dev-python/textX/Manifest b/dev-python/textX/Manifest
new file mode 100644
index 000000000000..2010f82f0da7
--- /dev/null
+++ b/dev-python/textX/Manifest
@@ -0,0 +1,2 @@
+DIST textX-1.4.tar.gz 21967 BLAKE2B b9e5b15715e370795470be855e0425075b1f704cab0ea2f24021345d8748f9f1a36e84618207c7684cadf86dae2ee0d613af3aaf217a881ba922385a544064ba SHA512 7783f4dd1358d8e0df126f1be893c58e32f57015fd577bd20d00a17b63111d6e48222c9b78420a307fcd0833f6d9ac3a1398d55986681251f7c378cdcd68c8a4
+DIST textX-3.0.0.gh.tar.gz 1827894 BLAKE2B 1b4dff3919838b8aa27faee9387fafd6771891b730c221e10a5f2593d138634950d6ced5a7344944913d99e591ed87adfac403add582baa50b0b94c9c6498572 SHA512 59b175a3f68b0a5b9b3522e814602c791df3fa7dffb8fabffdeed79ce746ae698ee61c748ce991d8cfee15e094c9437530912e84bdeed4531d0bd96d07477c90
diff --git a/dev-python/textX/metadata.xml b/dev-python/textX/metadata.xml
new file mode 100644
index 000000000000..de4b16fe0e05
--- /dev/null
+++ b/dev-python/textX/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>zmedico@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">textX</remote-id>
+		<remote-id type="github">textX/textX</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/textX/textX-1.4.ebuild b/dev-python/textX/textX-1.4.ebuild
new file mode 100644
index 000000000000..29f9dd96c99b
--- /dev/null
+++ b/dev-python/textX/textX-1.4.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{8..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Meta-language for DSL implementation inspired by Xtext"
+HOMEPAGE="https://pypi.org/project/textX/ https://github.com/igordejanovic/textX"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+# pypi tarball omits tests
+RESTRICT="test"
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="dev-python/arpeggio[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	py.test -v tests/functional || die "tests failed"
+}
diff --git a/dev-python/textX/textX-3.0.0.ebuild b/dev-python/textX/textX-3.0.0.ebuild
new file mode 100644
index 000000000000..79768ec8e29e
--- /dev/null
+++ b/dev-python/textX/textX-3.0.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Meta-language for DSL implementation inspired by Xtext"
+HOMEPAGE="
+	https://pypi.org/project/textX/
+	https://github.com/textX/textX/
+"
+SRC_URI="
+	https://github.com/textX/textX/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/arpeggio-2.0.0[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/click[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	# Update the shebang
+	sed -e "s:install/usr/bin/${EPYTHON}:test/usr/bin/${EPYTHON}:" \
+		-i "${BUILD_DIR}"/test/usr/bin/textx || die
+
+	# Install necessary plugins
+	local plugins=(
+		tests/functional/subcommands/example_project
+		tests/functional/registration/projects/*
+	)
+	local p
+	for p in "${plugins[@]}"; do
+		pushd "${p}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	epytest tests/functional
+}