dev-python/twine: Bump to 6.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/twine/Manifest b/dev-python/twine/Manifest
index 508da79d41f1..dfb924bb4b5a 100644
--- a/dev-python/twine/Manifest
+++ b/dev-python/twine/Manifest
@@ -1 +1,2 @@
 DIST twine-6.0.1.gh.tar.gz 223827 BLAKE2B ab88eb21908954ee7c32744ae9f7ccd7d50cb2b5207917144ef559e142837c89625596dea2c1bb0be21858bb0967690df999bb8a123e01beb5637a025dc490f9 SHA512 4fa7727d0728da3e05eaca068bf1dd85656225dd61958666ec0747359ee6bd88b25fd443d6c77bd8db245e71418cf8e5b594a6559ac1ecaafe3c079ecaefadba
+DIST twine-6.1.0.gh.tar.gz 163562 BLAKE2B c1fa279f62c5c6c5dfdc59120a9d80776d69527fec69356358963956ce7e1f76f05b432eaef3586c52a4150ce2893975cff252361740a7ce24b2917379c212f8 SHA512 d8235561f13eaaee7607b4b50dd70fdb67b9a9863a7d69fa2d173d8625cb3c44c8adccb27c5fe2203b3c1db7f36a685cc9da7f847aac3d5a3622b8e7125dd2b8
diff --git a/dev-python/twine/twine-6.1.0.ebuild b/dev-python/twine/twine-6.1.0.ebuild
new file mode 100644
index 000000000000..3705e5b5c78b
--- /dev/null
+++ b/dev-python/twine/twine-6.1.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of utilities for publishing packages on PyPI"
+HOMEPAGE="
+	https://twine.readthedocs.io/
+	https://github.com/pypa/twine/
+	https://pypi.org/project/twine/
+"
+SRC_URI="
+	https://github.com/pypa/twine/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/colorama-0.4.3[${PYTHON_USEDEP}]
+	dev-python/id[${PYTHON_USEDEP}]
+	>=dev-python/keyring-15.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	>=dev-python/readme-renderer-35.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-12.0.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/jaraco-envs[${PYTHON_USEDEP}]
+		dev-python/jaraco-functools[${PYTHON_USEDEP}]
+		dev-python/munch[${PYTHON_USEDEP}]
+		dev-python/portend[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pypiserver[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# pytest-socket dep relevant only to test_integration, and upstream
+	# disables it anyway
+	sed -i -e '/--disable-socket/d' pytest.ini || die
+	sed -i -e '/--cov/d' pytest.ini || die
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Internet
+		tests/test_integration.py
+	)
+	local EPYTEST_DESELECT=(
+		# Avoid needing heavy virtualx
+		tests/test_auth.py::test_warns_for_empty_password
+	)
+
+	local -x COLUMNS=80
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}