dev-python/ipykernel: Bump to 6.29.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 518d913f3104..4ca5f6133ec8 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1,2 +1,3 @@
 DIST ipykernel-6.29.0.tar.gz 160814 BLAKE2B 4f5c650fda125a477ae7f16fad07e968f0f31a97375159ff5d3917181f31ecac3a618927e492332e5d5f69321c43fad69daa4c9bdfc67acc3756775ef855ceec SHA512 f924d8c4471f04349e1c8d0b980f8759e55c37585a4a44e61ba01ed1b96e3aa3897ec6e953e91f8f881debf5e599ab95b679075dcd413e43b8ed0263e8c9ca44
 DIST ipykernel-6.29.1.tar.gz 161082 BLAKE2B f5f5d4f15d08594fbab78675cdc1575a5579b69adeb393fa35d3ef57f56ad642999e5d17a901287a7924d8f7d1b62625d1c81dd96c821ce43bc694a277c63389 SHA512 8691394e76b151561248f66802622a4e4863c51bc26b4cf44e468155ff0f82405b92e69c37ecca8181d4b71736f61658fbf59937e7607a94288c107ea4cbfd74
+DIST ipykernel-6.29.2.tar.gz 161175 BLAKE2B fc63fbaf01403933e7bcbb5b242e48f125a8349aeb2454a9bfd2f564e67f842af546fe4e69e447be2f4f6396d6aabcd6e29a6ff57424f5fcec0ebb1a43c50177 SHA512 5be2b1447b951304cabb7fbefae711aa2510dfd72ee03f0e2d9ec02e1cf44e541c9d8a11a87ab77a9338acb56db5c2cd82b11fa85f296c8a06ce6a8235e394b3
diff --git a/dev-python/ipykernel/ipykernel-6.29.2.ebuild b/dev-python/ipykernel/ipykernel-6.29.2.ebuild
new file mode 100644
index 000000000000..1bd0e3b093fe
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.29.2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	!elibc_Darwin? (
+		$(python_gen_cond_dep '
+			>=dev-python/debugpy-1.6.5[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-8[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest-asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_debugger.py::test_attach_debug
+		tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+		tests/test_debugger.py::test_rich_inspect_at_breakpoint
+		tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+		tests/test_debugger.py::test_set_breakpoints
+		tests/test_debugger.py::test_stop_on_breakpoint
+		tests/test_debugger.py::test_copy_to_globals
+		# hangs?
+		tests/test_eventloop.py::test_tk_loop
+		# doesn't like pyside2?
+		tests/test_eventloop.py::test_qt_enable_gui
+	)
+
+	virtx distutils-r1_src_test
+}