dev-ros/ament_cmake_cppcheck: bump to 0.10.4

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/dev-ros/ament_cmake_cppcheck/ament_cmake_cppcheck-0.10.4.ebuild b/dev-ros/ament_cmake_cppcheck/ament_cmake_cppcheck-0.10.4.ebuild
new file mode 100644
index 000000000000..33c0d35ad478
--- /dev/null
+++ b/dev-ros/ament_cmake_cppcheck/ament_cmake_cppcheck-0.10.4.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2019-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_7,3_8} )
+
+inherit cmake python-any-r1
+
+ROS_PN="ament_lint"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ament/ament_lint"
+	SRC_URI=""
+	S=${WORKDIR}/${P}/${PN}
+else
+	SRC_URI="https://github.com/ament/ament_lint/archive/${PV}.tar.gz -> ${ROS_PN}-${PV}.tar.gz"
+	S="${WORKDIR}/${ROS_PN}-${PV}/${PN}"
+fi
+
+DESCRIPTION="CMake API for ament_cppcheck to perform static code analysis on C/C++"
+HOMEPAGE="https://github.com/ament/ament_lint"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64"
+fi
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-ros/ament_cmake_test
+	dev-ros/ament_cmake_core
+	dev-ros/ament_cppcheck
+"
+DEPEND=""
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/ament_package[${PYTHON_USEDEP}] dev-python/catkin_pkg[${PYTHON_USEDEP}]')
+	dev-ros/ament_cmake_test
+	dev-ros/ament_cmake_core
+	test? (
+		dev-ros/ament_cmake_copyright
+		$(python_gen_any_dep 'dev-ros/ament_copyright[${PYTHON_USEDEP}]')
+		dev-ros/ament_cmake_lint_cmake
+	)
+	${PYTHON_DEPS}
+"
+
+python_check_deps() {
+	{ use !test || has_version -b "dev-ros/ament_copyright[${PYTHON_USEDEP}]"; } && \
+		has_version -b "dev-python/catkin_pkg[${PYTHON_USEDEP}]" && \
+		has_version -b "dev-python/ament_package[${PYTHON_USEDEP}]"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+	)
+	cmake_src_configure
+}