dev-ruby/actionmailbox: add 6.1.6.1

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-ruby/actionmailbox/actionmailbox-6.1.6.1.ebuild b/dev-ruby/actionmailbox/actionmailbox-6.1.6.1.ebuild
new file mode 100644
index 000000000000..5fabeb5d6ccd
--- /dev/null
+++ b/dev-ruby/actionmailbox/actionmailbox-6.1.6.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="actionmailbox.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_EXTRAINSTALL="app config db"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Framework for designing email-service layers"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/actionpack-${PV}
+	~dev-ruby/activejob-${PV}
+	~dev-ruby/activerecord-${PV}
+	~dev-ruby/activestorage-${PV}
+	~dev-ruby/activesupport-${PV}
+	>=dev-ruby/mail-2.7.1:*
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/bundler
+	dev-ruby/mocha
+	dev-ruby/rexml
+	dev-ruby/sqlite3
+	dev-ruby/webmock
+)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|mysql2\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|sass-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|sprockets\|stackprof\|websocket-client-simple\|libxml-ruby\|redis\|blade\|aws-sdk\|google-cloud\|azure-storage\|selenium\|webdrivers\|webrick\|minitest-bisect\|minitest-retry\|minitest-reporters\|listen\|rack-cache\|capybara\|webpacker\|bootsnap\|dalli\|connection_pool\)/ s:^:#:" \
+		-e '/group :\(cable\|doc\|job\|rubocop\|storage\|test\)/,/^end/ s:^:#:' \
+		-i ../Gemfile || die
+	rm ../Gemfile.lock || die
+	sed -i -e '/byebug/ s:^:#:' test/test_helper.rb || die
+}
+
+each_ruby_prepare() {
+	sed -i -e 's:ruby:'${RUBY}':' test/dummy/bin/* || die
+}