dev-util/pwntools: add 4.14.0

Signed-off-by: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/dev-util/pwntools/Manifest b/dev-util/pwntools/Manifest
index 4edfa7c59869..048a0a84179a 100644
--- a/dev-util/pwntools/Manifest
+++ b/dev-util/pwntools/Manifest
@@ -1,3 +1,4 @@
 DIST pwntools-4.13.0.gh.tar.gz 4388643 BLAKE2B 59a50621135e5e0fd247de37f9367d07155ab370fab5e5985a2e5900451d1d52b5b8362da2c1f59aaea36cfec9414345d2697256a4197fb0d31e90b4e58af45b SHA512 23511d60f619f7d6fb0cbe8389069e94c9b4ff33a3454c98e02db7b9ab591395511b56121f5bab7a8edd75ad06ca80154d379cda73acf61758e6d1215e463ed6
 DIST pwntools-4.13.1.gh.tar.gz 4388789 BLAKE2B e7f83e877f4f5b870bc7d2036d22746d997877c9de6bb76bf21010c6c5052d617670424d6a347455547085d385a165b7d00ca5c16b9789817690e5b128ba66d9 SHA512 9906b1f3abb747316ec2f6ce8ed23030a580ec07206ca1662f44eb9153be5d65bdfc4b9594778f6521be40e48acd48e2b6a83d4818161e2cc2eaae5ebeae7160
+DIST pwntools-4.14.0.gh.tar.gz 4423992 BLAKE2B 3b8eaad79947aac1da127f472f2ad32add81ef7c6493e50616206dba5ff0bd1383a06c89834ca2b8eb2fb18529a76fcd44fa1e72322cd728c21f46a58ea42111 SHA512 beab86689aa8c7b4b19c299ae0a3825153ddc2364adbc2208998de27fe6ceb6127578fdb7f4c767b1f54598e61cd3340a41e6785b1dacfe1b383ce33cc13e7a2
 DIST pwntools-4.14.0_beta1.gh.tar.gz 4423427 BLAKE2B e5240782f90098582342068296e0ce2fa3f8ba1f9600d273a8d83afca3ac95ba7fcef67e07c80044d4553a67a771d22f463caefef15bdca0f6f53db5cae87cc7 SHA512 b35ad15071633966637e5c9f45d4c0c0b897c1df946c2877a9c163ad041eb7da0203003615ae7d4aa2c8d3c558dd1b538e97d75e052ea864f0e6d8af20f33b1e
diff --git a/dev-util/pwntools/pwntools-4.14.0.ebuild b/dev-util/pwntools/pwntools-4.14.0.ebuild
new file mode 100644
index 000000000000..fc3a6da5c4dd
--- /dev/null
+++ b/dev-util/pwntools/pwntools-4.14.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+DISTUTILS_USE_PEP517=setuptools
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="CTF framework and exploit development library"
+HOMEPAGE="https://github.com/Gallopsled/pwntools"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Gallopsled/pwntools.git"
+else
+	SRC_URI="https://github.com/Gallopsled/pwntools/archive/${PV/_beta/beta}.tar.gz -> ${P}.gh.tar.gz"
+	if [[ ${PV} != *_beta* ]] ; then
+		KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+	fi
+	S="${WORKDIR}/${PN}-${PV/_beta/beta}"
+fi
+
+LICENSE="MIT GPL-2+ BSD-2"
+SLOT="0"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/capstone-3.0.5[python,${PYTHON_USEDEP}]
+	>=dev-util/ROPgadget-5.3[${PYTHON_USEDEP}]
+	>=dev-util/unicorn-1.0.2[python,${PYTHON_USEDEP}]
+	dev-python/colored-traceback[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0[${PYTHON_USEDEP}]
+	>=dev-python/mako-1.0.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-1.15.2[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyelftools-0.29[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyserial-2.7[${PYTHON_USEDEP}]
+	dev-python/pysocks[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0[${PYTHON_USEDEP}]
+	dev-python/rpyc[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.11.0_update_deps.patch"
+)
+
+python_configure_all() {
+	DISTUTILS_ARGS=(
+		--only-use-pwn-command
+	)
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newbashcomp extra/bash_completion.d/pwn pwn
+	newbashcomp extra/bash_completion.d/shellcraft shellcraft
+
+	insinto /usr/share/zsh/site-functions
+	doins extra/zsh_completion/_pwn
+
+	# Disable automatic update check (bug 915496).
+	insinto /etc
+	doins "${FILESDIR}/pwn.conf"
+
+	rm -r "${ED}/usr/pwntools-doc" || die
+}