dev-util/stepman: new ebuild, version 0.10.0

Closes: https://bugs.gentoo.org/661246
Closes: https://github.com/gentoo/gentoo/pull/9235

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-util/stepman/stepman-0.10.0.ebuild b/dev-util/stepman/stepman-0.10.0.ebuild
new file mode 100644
index 000000000000..4b0b891bc494
--- /dev/null
+++ b/dev-util/stepman/stepman-0.10.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-build
+
+EGO_ON="github.com/bitrise-io"
+EGO_PN="${EGO_ON}/${PN}"
+
+DESCRIPTION="Step collection manager for Bitrise CLI."
+HOMEPAGE="https://www.bitrise.io/cli"
+SRC_URI="https://${EGO_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+S="${WORKDIR}/src/${EGO_ON}/${PN}"
+
+src_unpack() {
+	unpack ${A}
+	mkdir -p "${WORKDIR}/src/${EGO_ON}" || die "Couldn't create project dir in GOPATH"
+	mv "${WORKDIR}/${P}" "${WORKDIR}/src/${EGO_ON}/stepman" || die "Couldn't move sources to GOPATH"
+}
+
+src_compile() {
+	GOPATH="${WORKDIR}" go build -v -o bin/stepman || die "Couldn't compile stepman"
+}
+
+src_test() {
+	export INTEGRATION_TEST_BINARY_PATH="${S}/bin/stepman"
+	GOPATH="${WORKDIR}" go test -v ./_tests/integration/... || die "Integration tests failed"
+}
+
+src_install() {
+	dobin bin/stepman
+	dodoc README.md
+}