dev-util/umockdev: Add dependency on net-libs/libpcap

Closes: https://bugs.gentoo.org/805170
Signed-off-by: Matt Turner <mattst88@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-util/umockdev/umockdev-0.16.1-r1.ebuild b/dev-util/umockdev/umockdev-0.16.1-r1.ebuild
new file mode 100644
index 000000000000..3326eb613894
--- /dev/null
+++ b/dev-util/umockdev/umockdev-0.16.1-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="Mock hardware devices for creating unit tests"
+HOMEPAGE="https://github.com/martinpitt/umockdev/"
+SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-libs/libpcap[${MULTILIB_USEDEP}]
+	virtual/libudev:=[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=dev-libs/gobject-introspection-1.32:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		dev-libs/libgudev:=[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	$(vala_depend)
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_src_prepare
+}
+
+multilib_src_configure() {
+	export VALAC="$(type -P valac-$(vala_best_api_version))"
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test --no-suite fails-valgrind
+}