dev-util/diffoscope: add 252

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 127 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index b708c77063ed..49fea3d6ba69 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,3 +1,4 @@
 DIST diffoscope-247.tar.bz2 3091118 BLAKE2B cb41b98d439c123b5ee5f458d635f08afebde1dad724f53a8227826a509bca5e94204855fcd4f220567552abc0a3ea93e1c4a6e16dea0ed32ce7587c15d4976c SHA512 ceaa55512373e9283e6a18a9c5c814cd5b3ee8a9e9721f69b924ee55644640ea28302029232a310fca4d92e53fb37886d3d5ce2c6b577742261c86df24f52740
 DIST diffoscope-250.tar.bz2 3093593 BLAKE2B bf7f41ed87c2ef4b5e4f89d6262711c3bb0f58f6925ec3c8865a2eb67d426848997af73442cb81391e2bec735ad65f548ba79fae76d05f6af9a5373cb81f02d6 SHA512 eae32b19f769b105254a07439912e2edbbb9ab2263cb05776c25366ed80b7290de925b5667287eb80eaaa5f4e4d99d81fc9fa4186346b0f5ec7da4651b3bdd4f
 DIST diffoscope-251.tar.bz2 3095764 BLAKE2B 13ac9b187f7e2722dd4998352291d320465798b8855ff2d2d1b6b47d01f2a0019b4809eb3da3ad5512d8e0be8415ff0f2a8883247e9b14e3a14f4312f87cd350 SHA512 ebe3a40dd0a0325948ba44e8d67799229c2a868f8f1a7dfad2a138a254cfd144eb2890292d2b8c381edc7ca7ea92fb7f804f67f92aa16e6e90c2cf2231c3491e
+DIST diffoscope-252.tar.bz2 3095888 BLAKE2B cdca839d60b9d65a0dea07ab7790719ce067f2f1af5aea97829a95e5ed7b25f009901266fc659d0f6ce6d2c80a873b79742c8604127c36a2cb865d756d11fdbb SHA512 565c85a5665fb4914820b76412b4bd40dbafc2fd7c1f2e641f13d29eaf2d62dd308a4c6b2b1f789547580dbe32cbab330987ad3ea55ab09f3854dab924b28950
diff --git a/dev-util/diffoscope/diffoscope-252.ebuild b/dev-util/diffoscope/diffoscope-252.ebuild
new file mode 100644
index 000000000000..b2232c7029e9
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-252.ebuild
@@ -0,0 +1,126 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+# No 3.12 yet as these two tests fail:
+# ERROR tests/comparators/test_elf.py::test_differences_with_dbgsym - TypeError: sequence item 1: expected str instance, bytes found
+# ERROR tests/comparators/test_elf.py::test_original_gnu_debuglink - TypeError: sequence item 1: expected str instance, bytes found
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+# We could use pypi, but upstream provide distribution tarballs, so let's use those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/pypdf[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( virtual/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence of filemagic's magic.py breaks imports
+# of dev-python/python-magic: bug #716482
+RDEPEND+=" !dev-python/filemagic"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+	test? (
+		app-text/docx2txt
+		app-text/html2text
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+	tests/comparators/test_gif.py::test_has_visuals
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+
+	# Fails on ZFS
+	tests/test_main.py::test_non_unicode_filename
+
+	# Fails on (unreleased) LLVM 16 with minor difference
+	#tests/comparators/test_macho.py::test_llvm_diff
+	#tests/comparators/test_elf.py::test_libmix_differences
+)
+
+distutils_enable_tests pytest