games-puzzle/sdl-jewels: Fix prefix, EAPI 8

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

2 files changed, 51 insertions, 43 deletions

diff --git a/games-puzzle/sdl-jewels/sdl-jewels-1.1.1-r1.ebuild b/games-puzzle/sdl-jewels/sdl-jewels-1.1.1-r1.ebuild
deleted file mode 100644
index e9f6f0422ae1..000000000000
--- a/games-puzzle/sdl-jewels/sdl-jewels-1.1.1-r1.ebuild
+++ /dev/null
@@ -1,43 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit desktop vcs-clean
-
-DESCRIPTION="Swap and match 3 or more jewels in a line in order to score points"
-HOMEPAGE="http://www.linuxmotors.com/gljewel/"
-SRC_URI="http://www.linuxmotors.com/gljewel/downloads/SDL_jewels-${PV}.tgz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-RESTRICT="test"
-
-RDEPEND="
-	media-libs/libsdl[opengl,video]
-	virtual/opengl
-"
-DEPEND="${RDEPEND}"
-
-S="${WORKDIR}/SDL_jewels-${PV}"
-
-src_prepare() {
-	default
-	eapply "${FILESDIR}/${P}-Makefile.patch"
-
-	# fix the data dir locations as it looks to be intended to run from src dir
-	sed -i -e "s|\"data\"|\"/usr/share/${PN}\"|" sound.c || die
-	sed -i -e "s|data/bigfont.ppm|/usr/share/${PN}/bigfont.ppm|" gljewel.c || die
-	ecvs_clean
-}
-
-src_install() {
-	dobin gljewel
-
-	insinto "/usr/share/${PN}"
-	doins -r data/*
-
-	einstalldocs
-	make_desktop_entry gljewel SDL_jewels
-}
diff --git a/games-puzzle/sdl-jewels/sdl-jewels-1.1.1-r2.ebuild b/games-puzzle/sdl-jewels/sdl-jewels-1.1.1-r2.ebuild
new file mode 100644
index 000000000000..f2b8a57c8bd5
--- /dev/null
+++ b/games-puzzle/sdl-jewels/sdl-jewels-1.1.1-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs vcs-clean
+
+DESCRIPTION="Swap and match 3 or more jewels in a line in order to score points"
+HOMEPAGE="https://www.linuxmotors.com/linux/gljewel/"
+SRC_URI="https://www.linuxmotors.com/linux/gljewel/downloads/SDL_jewels-${PV}.tgz"
+S="${WORKDIR}/SDL_jewels-${PV}"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="test"
+
+RDEPEND="
+	media-libs/libsdl[opengl,video]
+	media-libs/libglvnd[X]
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-Makefile.patch
+)
+
+src_prepare() {
+	default
+
+	# fix the data dir locations as it looks to be intended to run from src dir
+	sed -i -e "s|\"data\"|\"${EPREFIX}/usr/share/${PN}\"|" sound.c || die
+	sed -i -e "s|data/bigfont.ppm|${EPREFIX}/usr/share/${PN}/bigfont.ppm|" gljewel.c || die
+	ecvs_clean
+}
+
+src_configure() {
+	tc-export CC
+}
+
+src_install() {
+	dobin gljewel
+
+	insinto /usr/share/${PN}
+	doins -r data/*
+
+	einstalldocs
+	make_desktop_entry gljewel SDL_jewels
+}