games-roguelike/stone-soup: remove old

Signed-off-by: Erik Mackdanz <stasibear@gentoo.org>
Package-Manager: Portage-3.0.28, Repoman-3.0.3

2 files changed, 0 insertions, 202 deletions

diff --git a/games-roguelike/stone-soup/Manifest b/games-roguelike/stone-soup/Manifest
index 947355c01a2e..219fc18a5881 100644
--- a/games-roguelike/stone-soup/Manifest
+++ b/games-roguelike/stone-soup/Manifest
@@ -4,7 +4,6 @@ DIST stone-soup-0.26.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b6
 DIST stone-soup-0.26.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
 DIST stone-soup-0.27.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
 DIST stone-soup-0.27.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
-DIST stone-soup-0.28.0_pre20211128.tar.gz 16160462 BLAKE2B 91409e7e72a3024400aaa98645f374cae33955171fbc2311cae38df9099037e83bf92de6985ec9b9e7de5fe2e80f8a9f29471ff9a308888dca2624f3a42334c6 SHA512 6fd73326af7b17dcfe0874732551820b6b15f0f5124094d8dfced14ec2a7fa0dd9090dd4089f583310fe8f7cc4ab4377c812fc85ad3df05b32438c812acdcc8f
 DIST stone-soup-0.28.0_pre20211224.tar.gz 16229115 BLAKE2B 3c6ddbd667b05c56bfd4389091ce7d83ebf7c97dbcd0724b800fa0c409c21fd0e017ddf5e5a8776658a19125128af72a6edb35739b7b82a95ff05c0607ee4886 SHA512 8ace7a1269e4920841465cd26308730c04c4896cb8ecd0b8f031f47ccb8babd908b9617f79e6e336f1938b73ae8863244ae5eea7c25f16373b859eaea232b821
 DIST stone-soup-0.28.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
 DIST stone-soup-0.28.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
diff --git a/games-roguelike/stone-soup/stone-soup-0.28.0_pre20211128.ebuild b/games-roguelike/stone-soup/stone-soup-0.28.0_pre20211128.ebuild
deleted file mode 100644
index fe3f221a7170..000000000000
--- a/games-roguelike/stone-soup/stone-soup-0.28.0_pre20211128.ebuild
+++ /dev/null
@@ -1,201 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-{1..3} )
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-VIRTUALX_REQUIRED="manual"
-inherit desktop python-any-r1 lua-single xdg-utils toolchain-funcs
-
-DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting in dungeons"
-HOMEPAGE="https://crawl.develz.org"
-SLOT="0.28"
-
-# Leave empty string if not a _pre release
-COMMITSHA="bc3f381ebcfc7bc390c3495e054d1fb84b63bb7e"
-if [ -z "${COMMITSHA}" ]; then
-	# This is a proper release
-	SRC_URI="
-		https://github.com/crawl/crawl/releases/download/${PV}/${PN/-/_}-${PV}.zip
-		https://dev.gentoo.org/~stasibear/distfiles/${PN}.png -> ${PN}-${SLOT}.png
-		https://dev.gentoo.org/~stasibear/distfiles/${PN}.svg -> ${PN}-${SLOT}.svg
-	"
-	MY_P="stone_soup-${PV}"
-else
-	# This is a _pre release
-	SRC_URI="
-		https://github.com/crawl/crawl/archive/${COMMITSHA}.tar.gz -> ${P}.tar.gz
-		https://dev.gentoo.org/~stasibear/distfiles/${PN}.png -> ${PN}-${SLOT}.png
-		https://dev.gentoo.org/~stasibear/distfiles/${PN}.svg -> ${PN}-${SLOT}.svg
-	"
-	MY_P="crawl-${COMMITSHA}/crawl-ref"
-fi
-
-# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
-# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
-# Public Domain|CC0: most of tiles
-# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
-LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0 MIT"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug ncurses sound +tiles"
-
-S=${WORKDIR}/${MY_P}/source
-RDEPEND="
-	${LUA_DEPS}
-	dev-db/sqlite:3
-	sys-libs/zlib
-	!ncurses? ( !tiles? ( sys-libs/ncurses:0 ) )
-	ncurses? ( sys-libs/ncurses:0 )
-	tiles? (
-		media-fonts/dejavu
-		media-libs/freetype:2
-		media-libs/libpng:0
-		sound? (
-			   media-libs/libsdl2[X,opengl,sound,video]
-			   media-libs/sdl2-mixer
-		)
-		!sound? ( media-libs/libsdl2[X,opengl,video] )
-		media-libs/sdl2-image[png]
-		virtual/glu
-		virtual/opengl
-	)"
-DEPEND="${RDEPEND}
-	app-arch/unzip
-	dev-lang/perl
-	${PYTHON_DEPS}
-	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
-	sys-devel/flex
-	tiles? (
-		media-gfx/pngcrush
-		sys-libs/ncurses:0
-	)
-	virtual/pkgconfig
-	virtual/yacc
-	"
-
-PATCHES=(
-	"${FILESDIR}"/make.patch
-	"${FILESDIR}"/rltiles-make.patch
-)
-
-python_check_deps() {
-	has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-
-	python-any-r1_pkg_setup
-
-	if use !ncurses && use !tiles ; then
-		ewarn "Neither ncurses nor tiles frontend"
-		ewarn "selected, choosing ncurses only."
-		ewarn "Note that you can also enable both."
-	fi
-
-	if use sound && use !tiles ; then
-		ewarn "Sound support is only available with tiles."
-	fi
-}
-
-src_prepare() {
-	default
-	python_fix_shebang "${S}/util/species-gen.py"
-
-	sed -i -e "s/GAME = crawl$/GAME = crawl-${SLOT}/" "${S}/Makefile" \
-		|| die "Couldn't append slot to executable name"
-
-	# File required for a _pre build
-	if ! [ -f "${S}/util/release_ver" ]; then
-		echo "${SLOT}" >"${S}/util/release_ver" || die "Couldn't write release_ver"
-	fi
-}
-
-src_compile() {
-
-	# Insurance that we're not using bundled lib sources
-	rm -rf contrib || die "Couldn't delete contrib directory"
-
-	myemakeargs=(
-		$(usex debug "FULLDEBUG=y DEBUG=y" "")
-		BUILD_LUA=
-		AR="$(tc-getAR)"
-		CFOPTIMIZE=''
-		CFOTHERS="${CXXFLAGS}"
-		CONTRIBS=
-		DATADIR="/usr/share/${PN}-${SLOT}"
-		FORCE_CC="$(tc-getCC)"
-		FORCE_CXX="$(tc-getCXX)"
-		LDFLAGS="${LDFLAGS}"
-		MAKEOPTS="${MAKEOPTS}"
-		PKGCONFIG="$(tc-getPKG_CONFIG)"
-		RANLIB="$(tc-getRANLIB)"
-		SAVEDIR="~/.crawl-${SLOT}"
-		SOUND=$(usex sound "y" "")
-		STRIP=touch
-		USE_LUAJIT=
-		V=1
-		prefix="/usr"
-	)
-
-	if use ncurses || (use !ncurses && use !tiles) ; then
-		emake "${myemakeargs[@]}"
-		# move it in case we build both variants
-		use tiles && { mv "crawl-${SLOT}" "${WORKDIR}"/crawl-ncurses-${SLOT} || die ;}
-	fi
-
-	if use tiles ; then
-		emake "${myemakeargs[@]}" clean
-		emake "${myemakeargs[@]}" "TILES=y"
-	fi
-}
-
-src_test() {
-	emake "${myemakeargs[@]}" \
-		  $(usex tiles "TILES=y" "") \
-		  catch2-tests
-}
-
-src_install() {
-	emake "${myemakeargs[@]}" \
-		  $(usex tiles "TILES=y" "") \
-		  DESTDIR="${D}" \
-		  prefix_fp="" \
-		  bin_prefix="${D}/usr/bin" \
-		  install
-
-	[[ -e "${WORKDIR}/crawl-ncurses-${SLOT}" ]] && dobin "${WORKDIR}/crawl-ncurses-${SLOT}"
-
-	# don't relocate docs, needed at runtime
-	rm -rf "${D}/usr/share/${PN}-${SLOT}"/docs/license
-
-	mv "${WORKDIR}/${MY_P}"/docs/crawl.6 "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6" \
-	   || die "Couldn't append slot to man page name"
-	doman "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6"
-
-	# icons and menu for graphical build
-	if use tiles ; then
-		doicon -s 48 "${DISTDIR}"/${PN}-${SLOT}.png
-		doicon -s scalable "${DISTDIR}"/${PN}-${SLOT}.svg
-		make_desktop_entry "crawl-${SLOT}" "crawl-${SLOT}" "crawl-${SLOT}"
-	fi
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-
-	elog "crawl is a slotted install that supports having"
-	elog "multiple versions installed.  The binary has the"
-	elog "slot appended, e.g. 'crawl-"${SLOT}"'."
-
-	if use tiles && use ncurses ; then
-		elog
-		elog "Since you have enabled both tiles and ncurses frontends"
-		elog "the ncurses binary is called 'crawl-ncurses-"${SLOT}"' and the"
-		elog "tiles binary is called 'crawl-"${SLOT}"'."
-	fi
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-}