gnome-extra/gnome-calculator: Version bump to 3.38.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index ea4016b0730f..31b6192ef34c 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1 +1,2 @@
 DIST gnome-calculator-3.36.0.tar.xz 983532 BLAKE2B 5e28a82cb93cb944e69d4d7c7cf1a14cd91375ef864cbd5624d87a66ee79f0aff17f871ba734d35ae372b761ce67c809acb6fdfe66597980f33e06fe86d6157d SHA512 5e8d3b17703260928e9d0594a6e0b06b6a25d71590b4ab6c371e0c21be5e53698011407886f09f6bd67660ecbfa182d725d5e3a1c51fe4ea9125b175bd4d279c
+DIST gnome-calculator-3.38.2.tar.xz 1004684 BLAKE2B c2b6a0ff2e6a91c43a1670945af989b715f0f7369050dac13bec02898ef6780ec4484c6ee9f6e6bb19b8ecc9d7d8c2df0c824ac9c3309783cbc89b96fe1f16b9 SHA512 41e58b34640e795108a552aa0d95b03f0c84c4d5af6eef7fe8350c5f4e031a0fad7cad73034b38b2121f09687815b6b10a6a86fb00c7cbf720ccb06a8eea0403
diff --git a/gnome-extra/gnome-calculator/gnome-calculator-3.38.2.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-3.38.2.ebuild
new file mode 100644
index 000000000000..2d27114d9210
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-3.38.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_MIN_API_VERSION="0.40"
+
+inherit gnome.org gnome2-utils meson vala virtualx xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	>=dev-libs/libgee-0.20.0:0.8
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=x11-libs/gtk+-3.19.3:3
+	>=x11-libs/gtksourceview-4.0.2:4
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:2.4[vala]
+	x11-libs/gtksourceview:4[vala]
+"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+	# Automagic dep on valadoc - don't bother for now
+	sed -e '/subdir.*doc/d' -i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+		$(meson_use test ui-tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}