gnome-extra/gnome-dvb-daemon: EAPI6, python-single, py37, other fixes

* Port to EAPI-6 and drop some unnecessary eclass inherits
* The client code is all in python with shipped modules, so it has
  to be python-single-r1 instead of python-any-r1 (this happened
  to be fine with any due to only one python version supported
* Add python-3.7 support
* Drop totem plugin, as it can't function with in-tree totem anymore,
  because it doesn't support plugins changing the UI (in addition,
  the totem plugin was py2-only). Upstream has a grilo plugin now
  instead, but it has never been released before the whole project
  has fallen into de facto unmaintained status
* Drop useless USE=nls
* Drop USE=vala that doesn't do anything (the pregenerated C files
  are always used)
* Fix python module optimization handling
* Drop questionable libltdl dep
* Drop perl dep - it appears only used via intltool
* Standard subslot depend for gobject-introspection

In general I can't get this project to do anything useful, so help
maintaining and/or testing this welcome, if it has any actual users.
Or even letting me know how to get this going properly (I do have
a DVB-T USB device and some terrestial channels available).

Closes: https://bugs.gentoo.org/701202
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/gnome-extra/gnome-dvb-daemon/gnome-dvb-daemon-0.2.90-r1.ebuild b/gnome-extra/gnome-dvb-daemon/gnome-dvb-daemon-0.2.90-r1.ebuild
new file mode 100644
index 000000000000..f5d50bf32b3c
--- /dev/null
+++ b/gnome-extra/gnome-dvb-daemon/gnome-dvb-daemon-0.2.90-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Setup your DVB devices, record and watch TV shows and browse EPG using GStreamer"
+HOMEPAGE="https://wiki.gnome.org/Projects/DVBDaemon"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.32.0:2
+	dev-libs/libgudev:0
+	>=media-libs/gstreamer-1.4.0:1.0
+	>=media-libs/gst-plugins-good-1.4.0:1.0
+	>=media-libs/gst-plugins-bad-1.4.0:1.0
+	>=dev-libs/libgee-0.8:0.8
+	>=dev-db/sqlite-3.4:3
+	>=media-libs/gst-rtsp-server-1.4.5:1.0
+	media-plugins/gst-plugins-dvb:1.0
+	dev-python/gst-python:1.0
+	>=dev-python/pygobject-3.2.1:3
+	>=dev-libs/gobject-introspection-1.44.0:=
+	x11-libs/pango[introspection]
+	x11-libs/gtk+:3[introspection]
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40.0
+	>=dev-libs/libltdl-2.2.6:0
+	virtual/pkgconfig:0
+	>=sys-devel/gettext-0.18.1
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	# Prevent sandbox violations, bug #569992
+	addpredict /dev
+	gnome2_src_configure --disable-totem-plugin
+}
+
+src_install() {
+	gnome2_src_install
+	python_optimize
+}