kde-apps/ark: 23.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
index b9bb48b64c8d..1c1cf5da6c38 100644
--- a/kde-apps/ark/Manifest
+++ b/kde-apps/ark/Manifest
@@ -1 +1,2 @@
 DIST ark-23.04.3.tar.xz 3010636 BLAKE2B 93600fb21940839bafd25aabfb1ff346088b0bef7c49e1d73cc6b3e17d073dfca924caa747d2c0f3c70ccd63569aebc3d8a6d137c7503c9a17a1af1ab833b4b9 SHA512 6ca740fef459232cf7ff19d76b2ddcb080b8c9b34a0c718dae0875253417a6f3f8f9c4a7bd2bc5002ae06bb41eef7f958a40f0d54896680e82879ef0f1cbed10
+DIST ark-23.08.0.tar.xz 3016056 BLAKE2B d3ec1b07951f4aff70383d7d0748939e94bb4e26a09b16156613996c24f20a8d19623cd308b561c9f1bca71020e1435783fff8784b30d9ccfb55be3b5f67451b SHA512 84fc163e2f5c1b41d72978bb0f8a3e12aab68d681c7b2224dbf3b37bffd3c61814f54d1f647ec3aec34a2024275e7258f320fa2e692f2de08108999a2140d578
diff --git a/kde-apps/ark/ark-23.08.0.ebuild b/kde-apps/ark/ark-23.08.0.ebuild
new file mode 100644
index 000000000000..4211c086cbf3
--- /dev/null
+++ b/kde-apps/ark/ark-23.08.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org optfeature
+
+DESCRIPTION="File archiver by KDE"
+HOMEPAGE="https://apps.kde.org/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="zip"
+
+RDEPEND="
+	>=app-arch/libarchive-3.5.3:=[bzip2,lzma]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.6.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	test? ( >=dev-libs/libzip-1.6.0:= )
+"
+# app-arch/rar is binary only
+BDEPEND="
+	sys-devel/gettext
+	elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package zip LibZip)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# bug 822177: kerfuffle-addtoarchivetest: may segfault or hang indefinitely
+		# bug 827840: plugins-clirartest: continuously broken with translations installed
+		-E "(kerfuffle-addtoarchivetest|plugins-clirartest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "rar archive creation/extraction" "app-arch/rar"
+		optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
+		optfeature "7-Zip archive support" "app-arch/p7zip"
+		optfeature "lrz archive support" "app-arch/lrzip"
+		optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
+	fi
+	ecm_pkg_postinst
+}