kde-apps/cantor: drop 22.04.3

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 113 deletions

diff --git a/kde-apps/cantor/Manifest b/kde-apps/cantor/Manifest
index 380b15f3c15d..0429cd4cbc83 100644
--- a/kde-apps/cantor/Manifest
+++ b/kde-apps/cantor/Manifest
@@ -1,2 +1 @@
-DIST cantor-22.04.3.tar.xz 9196052 BLAKE2B 43d4386f0cf2bbe28f129491b066ce322f4f4936fad27e191302955409c1a336d7a9846b8254eaf5d4bbac5ac6d50023edfa3020921f5fcfc8c8a2d0fac130fa SHA512 aea0e1c545a05f46dfec8cf6e7d4a55d5d558e5965c2d15a568bcd38d2bb00f6abe184f976b2bbaab896367bb98ef04a1b4fa7c3af0fb30f0e90ad4d5c068a2c
 DIST cantor-22.08.3.tar.xz 9224356 BLAKE2B 28dbae0b86c16ec14d62a1ba277b7a34138bb32d7bf232f449874f8d19e64fe72a4fcaaeb072cf6d8f85e5ad8f425cb72e437f32a1927a8aba8a82df47e26d29 SHA512 e3f5fe79d63054c1cff1026372628a1db1b1e666570cec22f8b65f513544e5c798f1d43ab73dc5bf281ac887b8d92a50eda1c8bf41ee72ef09e2709c4869fb5a
diff --git a/kde-apps/cantor/cantor-22.04.3.ebuild b/kde-apps/cantor/cantor-22.04.3.ebuild
deleted file mode 100644
index af84ff76138a..000000000000
--- a/kde-apps/cantor/cantor-22.04.3.ebuild
+++ /dev/null
@@ -1,112 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CMAKE_MAKEFILE_GENERATOR="emake"
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="forceoptional"
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{8..11} )
-PVCUT=$(ver_cut 1-3)
-KFMIN=5.92.0
-QTMIN=5.15.4
-inherit ecm gear.kde.org lua-single optfeature python-single-r1
-
-DESCRIPTION="Interface for doing mathematics and scientific computing"
-HOMEPAGE="https://apps.kde.org/cantor/ https://edu.kde.org/cantor/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="amd64 arm64 x86"
-IUSE="+analitza julia lua postscript python qalculate R"
-
-REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} ) python? ( ${PYTHON_REQUIRED_USE} )"
-RESTRICT="test"
-
-# TODO Add Sage Mathematics Software backend (https://www.sagemath.org)
-DEPEND="
-	app-text/poppler[qt5]
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qthelp-${QTMIN}:5
-	>=dev-qt/qtprintsupport-${QTMIN}:5
-	>=dev-qt/qtsvg-${QTMIN}:5
-	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=dev-qt/qtxmlpatterns-${QTMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/knewstuff-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kpty-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
-	analitza? ( >=kde-apps/analitza-${PVCUT}:5 )
-	julia? ( dev-lang/julia )
-	lua? ( ${LUA_DEPS} )
-	qalculate? (
-		sci-libs/cln
-		sci-libs/libqalculate:=
-	)
-	postscript? ( app-text/libspectre )
-	python? (
-		${PYTHON_DEPS}
-		>=dev-qt/qtdbus-${QTMIN}:5
-	)
-	R? ( dev-lang/R )
-"
-RDEPEND="${DEPEND}
-	!analitza? ( !julia? ( !lua? ( !python? ( !qalculate? ( !R? (
-		|| (
-			sci-mathematics/maxima
-			sci-mathematics/octave
-		)
-	) ) ) ) ) )
-"
-BDEPEND="x11-misc/shared-mime-info"
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-	use python && python-single-r1_pkg_setup
-	ecm_pkg_setup
-}
-
-src_configure() {
-	use julia && addpredict /proc/self/mem # bug 602894
-
-	local mycmakeargs=(
-		$(cmake_use_find_package analitza Analitza5)
-		$(cmake_use_find_package julia Julia)
-		$(cmake_use_find_package lua LuaJIT)
-		-DUSE_LIBSPECTRE=$(usex postscript)
-		$(cmake_use_find_package python Python3)
-		$(cmake_use_find_package qalculate Qalculate)
-		$(cmake_use_find_package R R)
-	)
-	use lua && mycmakeargs+=(
-		-DLUAJIT_INCLUDEDIR="${EPREFIX}/$(lua_get_include_dir)"
-		-DLUAJIT_LIBDIR="${EPREFIX}/$(lua_get_cmod_dir)"
-	)
-	use python && mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
-	ecm_src_configure
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Maxima backend" sci-mathematics/maxima
-		optfeature "Octave backend" sci-mathematics/octave
-		optfeature "LaTeX support" virtual/latex-base
-	fi
-	ecm_pkg_postinst
-}