kde-apps/ksystemlog: 21.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-apps/ksystemlog/Manifest b/kde-apps/ksystemlog/Manifest
index 4e320bf3902d..6232cee62e47 100644
--- a/kde-apps/ksystemlog/Manifest
+++ b/kde-apps/ksystemlog/Manifest
@@ -1 +1,2 @@
 DIST ksystemlog-21.04.3.tar.xz 1958088 BLAKE2B 67a9be05e3525ca65be0eb10cd4bb1e1992eda8f55b487f64ef43691848c6a20ceb32be9585992dacea7cf41b8ef7c46d9ab25bcb20503e49c68eabf4d4f68c0 SHA512 c0af661b2898fbcb4cb81b46906bd09df86bebf3759a493d435b489500ee65b035207339340beec372e416485389ee093fd9187ab9c5f35cc71e1d94f31add2b
+DIST ksystemlog-21.08.0.tar.xz 1964092 BLAKE2B 6ed99444c7cf3af7d8b9a512c59898c7d1a867855807dc1ab279287a4b6a7f64ff593abe74c3fefff72ffcfa7a2626d56043c69a40f4e6fe72dd380813b1cbc3 SHA512 7c2a16dabc7bfbea3d0e9ae748b830cd67055c699bbc57912aa878b9b3e5d759fb3b0abcc292aec37815f243293ff829d5671bb43df4dc81127b80b8ad8a94c2
diff --git a/kde-apps/ksystemlog/ksystemlog-21.08.0.ebuild b/kde-apps/ksystemlog/ksystemlog-21.08.0.ebuild
new file mode 100644
index 000000000000..3d95998c2778
--- /dev/null
+++ b/kde-apps/ksystemlog/ksystemlog-21.08.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.84.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="System log viewer by KDE"
+HOMEPAGE="https://apps.kde.org/ksystemlog/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="audit kdesu systemd"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	audit? ( sys-process/audit )
+	systemd? ( sys-apps/systemd )
+"
+RDEPEND="${DEPEND}
+	kdesu? ( kde-plasma/kde-cli-tools[kdesu] )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use kdesu; then
+		sed -e "/^X-KDE-SubstituteUID/s:true:false:" \
+			-i src/org.kde.ksystemlog.desktop || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package audit Audit)
+		$(cmake_use_find_package systemd Journald)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	use kdesu || elog "Will show only user readable logs without USE=kdesu (only in X)."
+	use kdesu && elog "Cannot be launched from application menu in Wayland with USE=kdesu."
+}