kde-plasma/ksshaskpass: 5.20.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/kde-plasma/ksshaskpass/ksshaskpass-5.20.5.ebuild b/kde-plasma/ksshaskpass/ksshaskpass-5.20.5.ebuild
new file mode 100644
index 000000000000..4a4c8ddd91da
--- /dev/null
+++ b/kde-plasma/ksshaskpass/ksshaskpass-5.20.5.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.74.0
+QTMIN=5.15.1
+inherit ecm kde.org
+
+DESCRIPTION="Implementation of ssh-askpass with KDE Wallet integration"
+HOMEPAGE+=" https://invent.kde.org/plasma/ksshaskpass"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_install() {
+	ecm_src_install
+
+	insinto /etc/xdg/plasma-workspace/env/
+	doins "${FILESDIR}/05-ksshaskpass.sh"
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	elog "In order to have ssh-agent start with Plasma 5,"
+	elog "edit /etc/xdg/plasma-workspace/env/10-agent-startup.sh"
+	elog "and uncomment the lines enabling ssh-agent."
+	elog
+	elog "If you do so, do not forget to uncomment the respective"
+	elog "lines in /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
+	elog "to properly kill the agent when the session ends."
+	elog
+	elog "${PN} has been installed as your default askpass application"
+	elog "for Plasma 5 sessions."
+	elog "If that's not desired, select the one you want to use in"
+	elog "/etc/xdg/plasma-workspace/env/05-ksshaskpass.sh"
+
+	# Clean up pre-5.17.4 dirs
+	rmdir -v "${EROOT}"/etc/plasma{/startup,} 2> /dev/null
+}