proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 60 insertions, 0 deletions

diff --git a/mail-client/sylpheed/sylpheed-3.4.3.ebuild b/mail-client/sylpheed/sylpheed-3.4.3.ebuild
new file mode 100644
index 000000000000..5bd6d3803ee5
--- /dev/null
+++ b/mail-client/sylpheed/sylpheed-3.4.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils
+
+DESCRIPTION="A lightweight email client and newsreader"
+HOMEPAGE="http://sylpheed.sraoss.jp/"
+SRC_URI="http://${PN}.sraoss.jp/${PN}/v${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="crypt ipv6 ldap nls oniguruma pda spell ssl xface"
+
+CDEPEND="x11-libs/gtk+:2
+	crypt? ( app-crypt/gpgme )
+	ldap? ( net-nds/openldap )
+	nls? ( sys-devel/gettext )
+	oniguruma? ( dev-libs/oniguruma )
+	pda? ( app-pda/jpilot )
+	spell? ( app-text/gtkspell:2 )
+	ssl? ( dev-libs/openssl )"
+RDEPEND="${CDEPEND}
+	app-misc/mime-types
+	net-misc/curl"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	xface? ( media-libs/compface )"
+
+src_configure() {
+	local htmldir=/usr/share/doc/${PF}/html
+	econf \
+		$(use_enable crypt gpgme) \
+		$(use_enable ipv6) \
+		$(use_enable ldap) \
+		$(use_enable oniguruma) \
+		$(use_enable pda jpilot) \
+		$(use_enable spell gtkspell) \
+		$(use_enable ssl) \
+		$(use_enable xface compface) \
+		--with-manualdir=${htmldir}/manual \
+		--with-faqdir=${htmldir}/faq \
+		--disable-updatecheck
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog* NEWS* PLUGIN* README* TODO*
+
+	doicon *.png
+	domenu *.desktop
+
+	cd plugin/attachment_tool
+	docinto plugin/attachment_tool
+	emake DESTDIR="${D}" install-plugin
+	dodoc README
+}