mate-base/mate-session-manager: Bump to 1.24.1

Package-Manager: Portage-2.3.103, Repoman-2.3.23
RepoMan-Options: --force
Signed-off-by: Adam Feldman <NP-Hardass@gentoo.org>

3 files changed, 94 insertions, 0 deletions

diff --git a/mate-base/mate-session-manager/Manifest b/mate-base/mate-session-manager/Manifest
index a4e886a6e51c..5f83a57388b5 100644
--- a/mate-base/mate-session-manager/Manifest
+++ b/mate-base/mate-session-manager/Manifest
@@ -1 +1,2 @@
 DIST mate-session-manager-1.24.0.tar.xz 709712 BLAKE2B 6455872dfc89cdd3ced563a877e30ef59d2c6d94bd8f3b930eb778ea6b22a52ee860d785ba13d348e37e0d74526de4aef229d5c7b022e7f974ac949f553d7704 SHA512 ee519c8ded1f2df26e62a1384439e8929942d19560c258c91010f8d34bcc7518975406fbc0a5b76d4e73e954cdc2ea106d71476e446573d4a77d2704f6cc9e37
+DIST mate-session-manager-1.24.1.tar.xz 711188 BLAKE2B a2d48b53fbff6f2bf56cdf24efb709a17458341c75a37ab7494fcf344064b64f50e9527f11d74b681d2156508e24fefdb7a5c7637b72deddf1f3a82e4096031b SHA512 ca561e13080ef334a69f18b3aec0993532381ea5c178a0acf969bf2ed9cb5d484626404ab43d809727d8eef9b5eda29adc224168290f78a63da2621ac7ef79f5
diff --git a/mate-base/mate-session-manager/mate-session-manager-1.24.1.ebuild b/mate-base/mate-session-manager/mate-session-manager-1.24.1.ebuild
new file mode 100644
index 000000000000..0e8125acf23a
--- /dev/null
+++ b/mate-base/mate-session-manager/mate-session-manager-1.24.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="MATE session manager"
+HOMEPAGE="https://mate-desktop.org/"
+
+LICENSE="GPL-2+ GPL-3+ HPND LGPL-2+ LGPL-2.1+"
+SLOT="0"
+IUSE="debug elogind gles2 gnome-keyring ipv6 systemd +xtrans"
+
+REQUIRED_USE="?? ( elogind systemd )"
+
+# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
+# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
+# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).
+
+COMMON_DEPEND="
+	>=dev-libs/dbus-glib-0.76
+	>=dev-libs/glib-2.50:2
+	dev-libs/libxslt
+	sys-apps/dbus
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango
+	gles2? ( media-libs/mesa[egl,gles2] )
+	systemd? ( sys-apps/systemd )
+	!systemd? (
+		elogind? ( sys-auth/elogind )
+		!elogind? ( >=sys-auth/consolekit-0.9.2 )
+	)
+	xtrans? ( x11-libs/xtrans )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	mate-base/mate-desktop
+	virtual/libintl
+	x11-apps/xdpyinfo
+	x11-misc/xdg-user-dirs
+	x11-misc/xdg-user-dirs-gtk
+	gnome-keyring? ( gnome-base/gnome-keyring )
+	!<gnome-base/gdm-2.20.4
+"
+
+DEPEND="${COMMON_DEPEND}
+	>=dev-lang/perl-5
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+MATE_FORCE_AUTORECONF=true
+
+src_configure() {
+	mate_src_configure \
+		$(use_with elogind) \
+		$(use_with gles2 libglesv2) \
+		$(use_with systemd) \
+		$(use_with xtrans)  \
+		$(use_enable debug) \
+		$(use_enable ipv6)
+}
+
+src_install() {
+	mate_src_install
+
+	exeinto /etc/X11/Sessions/
+	doexe "${FILESDIR}"/MATE
+
+	insinto /usr/share/mate/applications/
+	doins "${FILESDIR}"/defaults.list
+
+	exeinto /etc/X11/xinit/xinitrc.d/
+	newexe "${FILESDIR}"/15-xdg-data-mate-r2 15-xdg-data-mate
+
+	# This should be done in MATE too, see Gentoo bug #270852
+	newexe "${FILESDIR}"/10-user-dirs-update-mate-r2 10-user-dirs-update-mate
+}
diff --git a/mate-base/mate-session-manager/metadata.xml b/mate-base/mate-session-manager/metadata.xml
index ee3469ab6dba..46d654532c7a 100644
--- a/mate-base/mate-session-manager/metadata.xml
+++ b/mate-base/mate-session-manager/metadata.xml
@@ -6,6 +6,7 @@
 		<name>Gentoo MATE Desktop</name>
 	</maintainer>
 	<use>
+		<flag name="gles2">Build with support for GLESv2 acceleration sessions</flag>
 		<flag name="xtrans">Build with Xtrans support; 
 		WARNING: Disabling this flag will result in ICE binding on all interfaces</flag>
 	</use>