media-gfx/flameshot: bump to v0.10.2

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Douglas Agbeve <douglas@agbeve.com>
Closes: https://github.com/gentoo/gentoo/pull/23090
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/media-gfx/flameshot/flameshot-0.10.2.ebuild b/media-gfx/flameshot/flameshot-0.10.2.ebuild
new file mode 100644
index 000000000000..f7e216a175dc
--- /dev/null
+++ b/media-gfx/flameshot/flameshot-0.10.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Powerful yet simple to use screenshot software"
+HOMEPAGE="https://flameshot.org https://github.com/flameshot-org/flameshot"
+SRC_URI="https://github.com/flameshot-org/flameshot/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 Free-Art-1.3 GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	=dev-qt/qtsingleapplication-2.6*[qt5(+),X]
+	dev-qt/qtwidgets:5
+	dev-qt/qtsvg:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtdbus:5
+	sys-apps/dbus
+	dev-libs/spdlog:=
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	rm -r external/spdlog || die
+	rm -r external/singleapplication || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_EXTERNAL_SPDLOG=1
+		-DUSE_EXTERNAL_SINGLEAPPLICATION=1
+		-DENABLE_CACHE=0
+	)
+
+	cmake_src_configure
+}