media-gfx/gmic: drop 3.2.5

Signed-off-by: Marek Szuba <marecki@gentoo.org>

2 files changed, 0 insertions, 140 deletions

diff --git a/media-gfx/gmic/Manifest b/media-gfx/gmic/Manifest
index e889e861285a..a17dec1164a6 100644
--- a/media-gfx/gmic/Manifest
+++ b/media-gfx/gmic/Manifest
@@ -1,3 +1,2 @@
 DIST gmic_3.2.0.tar.gz 10933655 BLAKE2B 6b87acb2a356d3d0c00e795d8b66de75acffa1f87b63caf58986ab52730fcd58bb9dfa37caf057ac2ab2a58695dd783c09018305f21d258427d9c1e450d1c14d SHA512 2eccf179e865416ce5a6cc38fd5587fe79fb30cda381ca2bcb1e587f101a55c502422121d4696834bc25b6200aa3c2292ff30947f2704a610f46e61460685f5b
-DIST gmic_3.2.5.tar.gz 11352319 BLAKE2B 812e28119bcbe485a7551c7afc89d7efb2a46ba3d9cc31597fddcd4c4ba48fa040827eccd92c1abbef3035c057d432f6b7b783ff9067da8be2806a05902bdf35 SHA512 e453b83201fa7aff7dc193c529c6b81306e94990a03356488abbbe3acdf8eb6b07e12c16e496e9607bcb730258218b3431c489b3fd1434bb31e28727be7eae27
 DIST gmic_3.2.6.tar.gz 11574989 BLAKE2B abd33048a448ca8406169c61a9d97bf6e785cbb286cec1d5104f12960640de9eb292677256c074eee5371fa77ed7041671f77a63140c2fa58070c01404962be6 SHA512 26b222c94d68273a8ad4a0c72dca315cb0e17695e601f69cb06d44c49166b8c1050926b8c5d73d21a64613e6ba3b0462e730617db83d2c67b53674bf22e50395
diff --git a/media-gfx/gmic/gmic-3.2.5.ebuild b/media-gfx/gmic/gmic-3.2.5.ebuild
deleted file mode 100644
index e49f4fe6fe0d..000000000000
--- a/media-gfx/gmic/gmic-3.2.5.ebuild
+++ /dev/null
@@ -1,139 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit toolchain-funcs
-
-DESCRIPTION="GREYC's Magic Image Converter"
-HOMEPAGE="https://gmic.eu/ https://github.com/GreycLab/gmic"
-SRC_URI="https://gmic.eu/files/source/${PN}_${PV}.tar.gz"
-
-LICENSE="CeCILL-2 GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="cli curl ffmpeg fftw gimp graphicsmagick jpeg opencv openexr openmp png qt5 tiff X"
-
-REQUIRED_USE="
-	gimp? ( png fftw X )
-	qt5? ( png fftw X )
-"
-
-MIN_QT_VER="5.2.0"
-QT_DEPEND="
-	>=dev-qt/qtcore-${MIN_QT_VER}:5
-	>=dev-qt/qtgui-${MIN_QT_VER}:5
-	>=dev-qt/qtnetwork-${MIN_QT_VER}:5
-	>=dev-qt/qtwidgets-${MIN_QT_VER}:5
-"
-DEPEND="
-	sys-libs/zlib:0=
-	curl? ( net-misc/curl )
-	fftw? ( sci-libs/fftw:3.0=[threads] )
-	gimp? (
-		media-gfx/gimp:0/2
-		${QT_DEPEND}
-	)
-	graphicsmagick? ( media-gfx/graphicsmagick:= )
-	jpeg? ( media-libs/libjpeg-turbo:= )
-	opencv? ( >=media-libs/opencv-2.3.1a-r1:= )
-	openexr? (
-		dev-libs/imath:=
-		media-libs/openexr:=
-	)
-	png? ( media-libs/libpng:= )
-	qt5? ( ${QT_DEPEND} )
-	tiff? ( media-libs/tiff:= )
-	X? (
-		x11-libs/libX11
-		x11-libs/libXext
-	)"
-RDEPEND="${DEPEND}
-	ffmpeg? ( media-video/ffmpeg:= )
-"
-BDEPEND="
-	virtual/pkgconfig
-	gimp? (
-		dev-qt/linguist-tools:5
-		media-gfx/gimp:0/2
-	)
-	qt5? ( dev-qt/linguist-tools:5 )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-3.1.6-ar_so.patch
-	"${FILESDIR}"/${PN}-3.2.0-grep38.patch
-	"${FILESDIR}"/${PN}-3.2.4-makefile_automagic.patch
-	"${FILESDIR}"/${PN}-3.2.5-relative_rpath.patch
-)
-
-pkg_pretend() {
-	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
-}
-
-pkg_setup() {
-	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
-}
-
-gmic_emake() {
-	local mymakeargs=(
-		CC="$(tc-getCC)"
-		CXX="$(tc-getCXX)"
-		STRIP="/bin/true"
-		LIB="$(get_libdir)"
-		OPT_CFLAGS="${CXXFLAGS}"
-		OPT_LIBS="${LDFLAGS}"
-		GMIC_USE_CURL=$(usex curl)
-		GMIC_USE_EXR=$(usex openexr)
-		GMIC_USE_FFTW=$(usex fftw)
-		GMIC_USE_GRAPHICSMAGICK=$(usex graphicsmagick)
-		GMIC_USE_JPEG=$(usex jpeg)
-		GMIC_USE_OPENCV=$(usex opencv)
-		GMIC_USE_OPENMP=$(usex openmp)
-		GMIC_USE_PNG=$(usex png)
-		GMIC_USE_TIFF=$(usex tiff)
-		GMIC_USE_X11=$(usex X)
-		QMAKE="qmake5"
-	)
-
-	# Possibly unnecessary since 3.2.0, just in case though.
-	tc-is-clang && mymakeargs+=( OPENMP_LIBS="-lomp" )
-
-	emake -j1 -C src \
-		"${mymakeargs[@]}" \
-		$@
-}
-
-src_compile() {
-	gmic_emake lib
-	gmic_emake libc
-	use cli && gmic_emake cli_shared
-	use gimp && gmic_emake gimp_shared
-	use qt5 && gmic_emake gmic_qt_shared
-}
-
-src_install() {
-	# See below for why this has to name a directory even if USE=-gimp
-	local gimp_plugindir="/deleteme"
-	if use gimp; then
-		if type gimptool &>/dev/null; then
-			gimp_plugindir="$(gimptool --gimpplugindir)/plug-ins"
-		elif type gimptool-2.0 &>/dev/null; then
-			gimp_plugindir="$(gimptool-2.0 --gimpplugindir)/plug-ins"
-		elif type gimptool-2.99 &>/dev/null; then
-			gimp_plugindir="$(gimptool-2.99 --gimpplugindir)/plug-ins"
-		else
-			die "Cannot find GIMP plugin directory"
-		fi
-	fi
-
-	gmic_emake DESTDIR="${ED}" PLUGINDIR="${gimp_plugindir}" install
-
-	# Upstream build scripts create PLUGINDIR and write some files to it
-	# regardless of whether the GIMP plug-in has been built or not, or even
-	# when they haven't been able to execute gimptool to get the base path.
-	use gimp || rm -rf "${ED}/${gimp_plugindir}"
-
-	# These are already gzipped in the source tarballs
-	find "${ED}/usr/share/man" -name "*.gz" -exec gunzip {} \; || die
-}