media-gfx/inkscape: Version bump 0.92.2 and ebuild fixes

Version bump to inkscape-0.92.2
Closes: https://bugs.gentoo.org/627536

Introduced >20kB patch for poppler-0.58.0 for this ebuild
Bug: https://bugs.gentoo.org/630482

Fixed invalid dependency on app-text/texlive in this ebuild
Bug: https://bugs.gentoo.org/625906

Also migrated from the obsolete 'fdo-mime' eclass to 'xdg-utils'

Removed eutils which was not needed here anymore since the EPAI=6 bump

Package-Manager: Portage-2.3.15, Repoman-2.3.5

2 files changed, 179 insertions, 0 deletions

diff --git a/media-gfx/inkscape/Manifest b/media-gfx/inkscape/Manifest
index 48745de6172b..fd58944c638b 100644
--- a/media-gfx/inkscape/Manifest
+++ b/media-gfx/inkscape/Manifest
@@ -1,2 +1,4 @@
 DIST inkscape-0.91.tar.bz2 25858909 SHA256 4d901f8a9e1924404e797ad23b8b0c495a9d155448816d95a55974314e1f141b SHA512 3778ef7d4a1c759a7afc093e55eefb69a78dcb60332655cc8ab8c481f54a3e6550df6070178390eb08588245531906b8bef33301f0765a4d28d6c7506fcf3bc7 WHIRLPOOL ff538bd47dbea3bc461f24b09f2d26e3b6141053e8289bac1ac973b65b6957257c5aede30e782201c2813919643bf23989c7ce6a8492fa259b3d506e427e4126
+DIST inkscape-0.92.1-poppler.patch 44142 SHA256 e6b35d9c9967d0b87170a2a6d39dc5e210dee0c37dd71bab6fa2cb5915a3a538 SHA512 4a0504c236c816f413b3bf055754513bb53b52eb5f0323faa28ab445ce3fb83b6f41de5bc6e3865909e50fc9be937e3f99282e8414f4cdc954e04b974d7f15ab WHIRLPOOL 90d8ba0d2d54d4175fcbbf9236772dfcc0495083ae31a88bdf26055d9dc68025e268a0667d9be644b62f1aca4663e25ca5a407befb364f66fdef4a738e80c714
 DIST inkscape-0.92.1.tar.bz2 31222684 SHA256 257405bf802de125f17d123638093a37db02ebe334d243cf9b0d8903f7c89005 SHA512 f8f3bfb812a214216c3ffac7064a4619f847cf9810417c782481dba12e6c6a44123c8b8a9289fbf5287f2e6b6df39a641d94a000d842faee5ff808eec86187a0 WHIRLPOOL f8134aed9ddb174fda88e13c201cf9099604e9591228ec306feeabaeee859f657961370ba4d1420f51e5e520f3543d7d129577144d9221e52f638a9f0bf81493
+DIST inkscape-0.92.2.tar.bz2 31224100 SHA256 a628d0e04c254e9840947e6d866974f92c68ae31631a38b94d9b65e5cd84cfd3 SHA512 e790cafb7cc2be2eb75f04ac4c18ae8558ae997f4261c38dac9c2a3383c7a12a0f4a090956770d1341b212fc9698d31d212f2c1609421907255f8af650569b30 WHIRLPOOL a654da639877824a6b7e4f894d3a5bf59cea2825d683527d90b1b4770852ce48db291156baf9ca0924d9fdba5cfcde9efb02a140124dacce67cd360743277019
diff --git a/media-gfx/inkscape/inkscape-0.92.2.ebuild b/media-gfx/inkscape/inkscape-0.92.2.ebuild
new file mode 100644
index 000000000000..f91ae073ba53
--- /dev/null
+++ b/media-gfx/inkscape/inkscape-0.92.2.ebuild
@@ -0,0 +1,177 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml"
+
+inherit autotools flag-o-matic gnome2-utils xdg toolchain-funcs python-single-r1
+
+MY_P=${P/_/}
+
+DESCRIPTION="A SVG based generic vector-drawing program"
+HOMEPAGE="https://inkscape.org/"
+SRC_URI="https://inkscape.global.ssl.fastly.net/media/resources/file/${P}.tar.bz2
+https://dev.gentoo.org/~jstein/dist/inkscape-0.92.1-poppler.patch"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="cdr dia dbus exif gnome imagemagick openmp postscript inkjar jpeg latex"
+IUSE+=" lcms nls spell static-libs visio wpg"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+WPG_DEPS="
+	|| (
+		( app-text/libwpg:0.3 dev-libs/librevenge )
+		( app-text/libwpd:0.9 app-text/libwpg:0.2 )
+	)
+"
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=app-text/poppler-0.26.0:=[cairo]
+	>=dev-cpp/glibmm-2.48
+	>=dev-cpp/gtkmm-2.18.0:2.4
+	>=dev-cpp/cairomm-1.9.8
+	>=dev-libs/boehm-gc-7.1
+	>=dev-libs/glib-2.28
+	>=dev-libs/libsigc++-2.0.12
+	>=dev-libs/libxml2-2.6.20
+	>=dev-libs/libxslt-1.0.15
+	dev-libs/popt
+	dev-python/lxml[${PYTHON_USEDEP}]
+	media-gfx/potrace
+	media-gfx/scour[${PYTHON_USEDEP}]
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/libpng:0
+	sci-libs/gsl:=
+	x11-libs/libX11
+	>=x11-libs/gtk+-2.10.7:2
+	>=x11-libs/pango-1.24
+	cdr? (
+		media-libs/libcdr
+		${WPG_DEPS}
+	)
+	dbus? ( dev-libs/dbus-glib )
+	exif? ( media-libs/libexif )
+	gnome? ( >=gnome-base/gnome-vfs-2.0 )
+	imagemagick? ( media-gfx/imagemagick:=[cxx] )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	spell? (
+		app-text/aspell
+		app-text/gtkspell:2
+	)
+	visio? (
+		media-libs/libvisio
+		${WPG_DEPS}
+	)
+	wpg? ( ${WPG_DEPS} )
+"
+
+# These only use executables provided by these packages
+# See share/extensions for more details. inkscape can tell you to
+# install these so we could of course just not depend on those and rely
+# on that.
+RDEPEND="${COMMON_DEPEND}
+	dev-python/numpy[${PYTHON_USEDEP}]
+	media-gfx/uniconvertor
+	dia? ( app-office/dia )
+	latex? (
+		media-gfx/pstoedit[plotutils]
+		app-text/dvipsk
+		app-text/texlive-core
+	)
+	postscript? ( app-text/ghostscript-gpl )
+"
+
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.36
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.92.1-automagic.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-cppflags.patch"
+	"${FILESDIR}/${PN}-0.92.1-desktop.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-exif.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-sk-man.patch"
+	"${FILESDIR}/${PN}-0.48.4-epython.patch"
+	"${DISTDIR}/${PN}-0.92.1-poppler.patch"
+)
+
+S=${WORKDIR}/${MY_P}
+
+RESTRICT="test"
+
+pkg_pretend() {
+	if use openmp; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed -i "s#@EPYTHON@#${EPYTHON}#" \
+		src/extension/implementation/script.cpp || die
+
+	eautoreconf
+
+	# bug 421111
+	python_fix_shebang share/extensions
+}
+
+src_configure() {
+	# aliasing unsafe wrt #310393
+	append-flags -fno-strict-aliasing
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable nls) \
+		$(use_enable openmp) \
+		$(use_enable exif) \
+		$(use_enable jpeg) \
+		$(use_enable lcms) \
+		--enable-poppler-cairo \
+		$(use_enable wpg) \
+		$(use_enable visio) \
+		$(use_enable cdr) \
+		$(use_enable dbus dbusapi) \
+		$(use_enable imagemagick magick) \
+		$(use_with gnome gnome-vfs) \
+		$(use_with inkjar) \
+		$(use_with spell gtkspell) \
+		$(use_with spell aspell)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	prune_libtool_files
+	python_optimize "${ED}"/usr/share/${PN}/extensions
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}